Version bump, bug #521370. Fix missing USE=dynamic deps, https://bugs.funtoo.org/browse/FL-2074.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 125 insertions, 2 deletions

diff --git a/media-sound/cantata/ChangeLog b/media-sound/cantata/ChangeLog
index 8192fe4c579a..6fdfdcda2e72 100644
--- a/media-sound/cantata/ChangeLog
+++ b/media-sound/cantata/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/cantata
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/cantata/ChangeLog,v 1.29 2014/12/07 12:41:07 mrueg Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/cantata/ChangeLog,v 1.30 2015/02/03 16:23:20 mgorny Exp $
+
+*cantata-1.5.1 (03 Feb 2015)
+
+  03 Feb 2015; Michał Górny <mgorny@gentoo.org> +cantata-1.5.1.ebuild:
+  Version bump, bug #521370. Fix missing USE=dynamic deps,
+  https://bugs.funtoo.org/browse/FL-2074.
 
   07 Dec 2014; Manuel Rüger <mrueg@gentoo.org> cantata-1.3.3.ebuild,
   cantata-1.3.4.ebuild:
diff --git a/media-sound/cantata/cantata-1.5.1.ebuild b/media-sound/cantata/cantata-1.5.1.ebuild
new file mode 100644
index 000000000000..baf9f283299a
--- /dev/null
+++ b/media-sound/cantata/cantata-1.5.1.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/cantata/cantata-1.5.1.ebuild,v 1.1 2015/02/03 16:23:20 mgorny Exp $
+
+EAPI=5
+
+KDE_REQUIRED="optional"
+PLOCALES="cs de en_GB es hu ko pl ru zh_CN"
+inherit kde4-base l10n
+
+DESCRIPTION="Featureful and configurable Qt client for the music player daemon (MPD)"
+HOMEPAGE="https://code.google.com/p/cantata/"
+SRC_URI="https://drive.google.com/uc?export=download&id=0Bzghs6gQWi60UktwaTRMTjRIUW8 -> ${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="4"
+KEYWORDS="~amd64 ~x86"
+IUSE="cddb cdda dynamic http-server kde lame mtp musicbrainz online-services qt5 replaygain streams taglib udisks"
+REQUIRED_USE="
+	cddb? ( cdda taglib )
+	cdda? ( udisks || ( cddb musicbrainz )  )
+	lame? ( cdda taglib )
+	mtp? ( taglib udisks )
+	musicbrainz? ( cdda taglib )
+	online-services? ( taglib )
+	qt5? ( !kde )
+	replaygain? ( taglib )
+"
+
+RDEPEND="
+	dev-libs/qjson
+	sys-libs/zlib
+	x11-libs/libX11
+	|| ( kde-apps/oxygen-icons $(add_kdebase_dep oxygen-icons) )
+	cdda? ( media-sound/cdparanoia )
+	cddb? ( media-libs/libcddb )
+	kde? ( $(add_kdebase_dep kwalletd) )
+	lame? ( media-sound/lame )
+	mtp? ( media-libs/libmtp )
+	musicbrainz? ( media-libs/musicbrainz:5 )
+	qt5? (
+		dev-qt/qtconcurrent:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtxml:5
+	)
+	!qt5? (
+		dev-qt/qtcore:4
+		dev-qt/qtdbus:4
+		dev-qt/qtgui:4
+		dev-qt/qtsvg:4
+	)
+	replaygain? (
+		media-sound/mpg123
+		virtual/ffmpeg
+	)
+	taglib? (
+		media-libs/taglib[asf,mp4]
+		media-libs/taglib-extras
+		!kde? ( udisks? ( sys-fs/udisks:2 ) )
+	)
+"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+"
+RDEPEND="${RDEPEND}
+	dynamic? (
+		dev-lang/perl[ithreads]
+		dev-perl/URI
+	)
+"
+
+# cantata has no tests
+RESTRICT="test"
+
+src_prepare() {
+	kde4-base_src_prepare
+
+	rm -rf 3rdparty/qtsingleapplication/ || die
+	# qjson ebuild does not support Qt5 yet
+	use qt5 || { rm -rf 3rdparty/qjson/ || die ;}
+	use kde && { rm -rf 3rdparty/solid-lite/ || die ;}
+
+	l10n_find_plocales_changes 'po' '' '.po'
+}
+
+src_configure() {
+	local langs="$(l10n_get_locales)"
+
+	local mycmakeargs=(
+		-DCANTATA_TRANSLATIONS="${langs// /;}"
+		$(cmake-utils_use_enable cdda CDPARANOIA)
+		$(cmake-utils_use_enable cddb)
+		$(cmake-utils_use_enable dynamic)
+		$(cmake-utils_use_enable http-server HTTP_SERVER)
+		$(cmake-utils_use_enable kde)
+		$(cmake-utils_use_enable kde kwallet)
+		$(cmake-utils_use_enable lame)
+		$(cmake-utils_use_enable mtp)
+		$(cmake-utils_use_enable musicbrainz)
+		$(cmake-utils_use_enable online-services ONLINE_SERVICES)
+		$(cmake-utils_use_enable streams)
+		$(cmake-utils_use_enable qt5)
+		$(cmake-utils_use_enable replaygain FFMPEG)
+		$(cmake-utils_use_enable replaygain MPG123)
+		$(cmake-utils_use_enable taglib)
+		$(cmake-utils_use_enable taglib TAGLIB_EXTRAS)
+		$(cmake-utils_use_enable udisks DEVICES_SUPPORT)
+		-DENABLE_HTTP_STREAM_PLAYBACK=OFF
+		-DENABLE_REMOTE_DEVICES=OFF
+		-DENABLE_UDISKS2=ON
+		-DUSE_SYSTEM_MENU_ICON=OFF
+	)
+
+	kde4-base_src_configure
+}