Restore gtk2 option for users who want to avoid gtk3 (the new default for this package). Since upstream still offers this option, we should not take this option away from our users.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x0F9C590B7FF324F6!)

3 files changed, 90 insertions, 1 deletions

diff --git a/media-sound/easytag/ChangeLog b/media-sound/easytag/ChangeLog
index ebb4a16927a9..ad6e8c841dd5 100644
--- a/media-sound/easytag/ChangeLog
+++ b/media-sound/easytag/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for media-sound/easytag
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/easytag/ChangeLog,v 1.186 2014/04/17 07:19:59 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/easytag/ChangeLog,v 1.187 2014/04/20 08:17:07 yngwin Exp $
+
+*easytag-2.2.0-r1 (20 Apr 2014)
+
+  20 Apr 2014; Ben de Groot <yngwin@gentoo.org> +easytag-2.2.0-r1.ebuild,
+  metadata.xml:
+  Restore gtk2 option for users who want to avoid gtk3 (the new default for this
+  package). Since upstream still offers this option, we should not take this
+  option away from our users.
 
   17 Apr 2014; Samuli Suominen <ssuominen@gentoo.org> easytag-2.2.0.ebuild:
   Pull in latest dependencies because upstream.ac is not up to date wrt #507570
diff --git a/media-sound/easytag/easytag-2.2.0-r1.ebuild b/media-sound/easytag/easytag-2.2.0-r1.ebuild
new file mode 100644
index 000000000000..d4d165e7a01a
--- /dev/null
+++ b/media-sound/easytag/easytag-2.2.0-r1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/easytag/easytag-2.2.0-r1.ebuild,v 1.1 2014/04/20 08:17:07 yngwin Exp $
+
+EAPI=5
+inherit gnome.org gnome2-utils fdo-mime
+
+DESCRIPTION="GTK+ utility for editing MP2, MP3, MP4, FLAC, Ogg and other media tags"
+HOMEPAGE="https://wiki.gnome.org/Apps/EasyTAG"
+
+LICENSE="GPL-2 GPL-2+ LGPL-2 LGPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~x86 ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE="flac gtk2 +gtk3 mp3 opus speex test wavpack"
+REQUIRED_USE="|| ( gtk2 gtk3 )"
+
+RDEPEND=">=dev-libs/glib-2.32:2
+	>=media-libs/libogg-1.3.1
+	>=media-libs/libvorbis-1.3.4
+	>=media-libs/taglib-1.9.1[mp4]
+	flac? ( >=media-libs/flac-1.3 )
+	gtk2? ( >=x11-libs/gtk+-2.24:2 )
+	gtk3? ( >=x11-libs/gtk+-3.4:3 )
+	mp3? (
+		>=media-libs/id3lib-3.8.3-r8
+		>=media-libs/libid3tag-0.15.1b-r4
+		)
+	opus? (
+		>=media-libs/opus-1.1
+		>=media-libs/opusfile-0.4
+		)
+	speex? ( >=media-libs/speex-1.2_rc1 )
+	wavpack? ( >=media-sound/wavpack-4.70 )"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.4
+	app-text/yelp-tools
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-util/intltool-0.50
+	>=sys-devel/gettext-0.18.3.2
+	virtual/pkgconfig
+	!<dev-util/pkgconfig-0.27
+	test? (
+		>=dev-util/appdata-tools-0.1.7
+		|| ( >=dev-util/desktop-file-utils-22 <dev-util/desktop-file-utils-22 )
+		)"
+
+src_prepare() {
+	sed -i \
+		-e '/^DEPRECATED_CPPFLAGS="/d' \
+		-e '/warning_flags/s: -Werror=.*:":' \
+		configure || die
+}
+
+DOCS=( AUTHORS ChangeLog HACKING NEWS README THANKS TODO )
+
+src_configure() {
+	# Kludge to make easytag find its locales (bug #503698)
+	export DATADIRNAME=share
+
+	# FIXME: src/gio_wrapper.h -> taglib #include without #ifdef -> --enable-mp4
+	# FIXME: src/vcedit.h -> ogg and vorbis #include without #ifdef -> --enable-ogg
+	econf \
+		$(use_enable test appdata-validate) \
+		$(use_enable test tests) \
+		$(use_enable mp3) \
+		$(use_enable mp3 id3v23) \
+		--enable-ogg \
+		$(use_enable opus) \
+		$(use_enable speex) \
+		$(use_enable flac) \
+		--enable-mp4 \
+		$(use_enable wavpack) \
+		$(use_with gtk2)
+}
+
+pkg_preinst() { gnome2_icon_savelist; }
+pkg_postinst() { gnome2_icon_cache_update; fdo-mime_desktop_database_update; }
+pkg_postrm() { gnome2_icon_cache_update; fdo-mime_desktop_database_update; }
diff --git a/media-sound/easytag/metadata.xml b/media-sound/easytag/metadata.xml
index a9fff8a9fd87..b11db7f26094 100644
--- a/media-sound/easytag/metadata.xml
+++ b/media-sound/easytag/metadata.xml
@@ -4,6 +4,8 @@
   <herd>sound</herd>
   <use>
     <flag name='opus'>Enable support for <pkg>media-libs/opus</pkg> and <pkg>media-libs/opusfile</pkg> (opus audio codec)</flag>
+	<flag name='gtk2'>Enable GTK+:2 support and disable default GTK+:3 support</flag>
+	<flag name='gtk3'>Enable GTK+:3 support (default) and disable GTK+:2 support</flag>
   </use>
   <longdescription>a utility for viewing and editing tags for MP3, MP2, FLAC, AAC, MP4 and OGG files. It features a simple and attractive GTK+ interface</longdescription>
 </pkgmetadata>