Version bump.

(Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 110 insertions, 1 deletions

diff --git a/media-sound/lilypond/ChangeLog b/media-sound/lilypond/ChangeLog
index 563b8fe693bb..029e8332a4f8 100644
--- a/media-sound/lilypond/ChangeLog
+++ b/media-sound/lilypond/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/lilypond
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/lilypond/ChangeLog,v 1.148 2013/04/16 09:18:32 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/lilypond/ChangeLog,v 1.149 2013/05/09 05:57:17 radhermit Exp $
+
+*lilypond-2.17.17 (09 May 2013)
+
+  09 May 2013; Tim Harder <radhermit@gentoo.org> +lilypond-2.17.17.ebuild:
+  Version bump.
 
 *lilypond-2.17.16 (16 Apr 2013)
 
diff --git a/media-sound/lilypond/lilypond-2.17.17.ebuild b/media-sound/lilypond/lilypond-2.17.17.ebuild
new file mode 100644
index 000000000000..6dffa70c06cb
--- /dev/null
+++ b/media-sound/lilypond/lilypond-2.17.17.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/lilypond/lilypond-2.17.17.ebuild,v 1.1 2013/05/09 05:57:17 radhermit Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_5,2_6,2_7} )
+
+inherit elisp-common autotools eutils python-single-r1
+
+DESCRIPTION="GNU Music Typesetter"
+SRC_URI="http://download.linuxaudio.org/lilypond/sources/v${PV:0:4}/${P}.tar.gz"
+HOMEPAGE="http://lilypond.org/"
+
+SLOT="0"
+LICENSE="GPL-3 FDL-1.3"
+KEYWORDS="~amd64 ~hppa ~x86"
+LANGS=" ca cs da de el eo es fi fr it ja nl ru sv tr uk vi zh_TW"
+IUSE="debug emacs profile vim-syntax ${LANGS// / linguas_}"
+
+RDEPEND=">=app-text/ghostscript-gpl-8.15
+	>=dev-scheme/guile-1.8.2[deprecated,regex]
+	media-fonts/urw-fonts
+	media-libs/fontconfig
+	media-libs/freetype:2
+	>=x11-libs/pango-1.12.3
+	emacs? ( virtual/emacs )
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	app-text/t1utils
+	dev-lang/perl
+	dev-texlive/texlive-metapost
+	virtual/pkgconfig
+	media-gfx/fontforge
+	>=sys-apps/texinfo-4.11
+	>=sys-devel/bison-2.0
+	sys-devel/flex
+	sys-devel/gettext
+	sys-devel/make"
+
+# Correct output data for tests isn't bundled with releases
+RESTRICT="test"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.17.2-tex-docs.patch
+
+	if ! use vim-syntax ; then
+		sed -i -e "s/vim//" GNUmakefile.in || die
+	fi
+
+	sed -i -e "s/OPTIMIZE -g/OPTIMIZE/" aclocal.m4 || die
+
+	for lang in ${LANGS}; do
+		use linguas_${lang} || rm po/${lang}.po || die
+	done
+
+	eautoreconf
+}
+
+src_configure() {
+	# documentation generation currently not supported since it requires a newer
+	# version of texi2html than is currently in the tree
+
+	econf \
+		--with-ncsb-dir=/usr/share/fonts/urw-fonts \
+		--disable-documentation \
+		--disable-optimising \
+		--disable-pipe \
+		$(use_enable debug debugging) \
+		$(use_enable profile profiling)
+}
+
+src_compile() {
+	default
+
+	if use emacs ; then
+		elisp-compile elisp/lilypond-{font-lock,indent,mode,what-beat}.el \
+			|| die "elisp-compile failed"
+	fi
+}
+
+src_install () {
+	emake DESTDIR="${D}" vimdir=/usr/share/vim/vimfiles install
+
+	# remove elisp files since they are in the wrong directory
+	rm -r "${ED}"/usr/share/emacs || die
+
+	if use emacs ; then
+		elisp-install ${PN} elisp/*.{el,elc} elisp/out/*.el \
+			|| die "elisp-install failed"
+		elisp-site-file-install "${FILESDIR}"/50${PN}-gentoo.el
+	fi
+
+	python_fix_shebang "${ED}"
+
+	dodoc AUTHORS.txt HACKING NEWS.txt README.txt
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}