Version bump, this upstream release is more resilient against large-file mismatches between library & application and fixes an invalid memory access bug resulting from a bad alignment algorithm.

(Portage version: 2.1.8.3/cvs/Linux x86_64)

2 files changed, 72 insertions, 1 deletions

diff --git a/media-sound/mpg123/ChangeLog b/media-sound/mpg123/ChangeLog
index e81249b4af01..632234c32b62 100644
--- a/media-sound/mpg123/ChangeLog
+++ b/media-sound/mpg123/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/mpg123
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.229 2010/06/08 14:54:30 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.230 2010/06/21 11:25:41 chainsaw Exp $
+
+*mpg123-1.12.2 (21 Jun 2010)
+
+  21 Jun 2010; <chainsaw@gentoo.org> +mpg123-1.12.2.ebuild:
+  Version bump, this upstream release is more resilient against large-file
+  mismatches between library & application and fixes an invalid memory
+  access bug resulting from a bad alignment algorithm.
 
   08 Jun 2010; <chainsaw@gentoo.org> mpg123-1.9.2.ebuild,
   -mpg123-1.10.1.ebuild:
diff --git a/media-sound/mpg123/mpg123-1.12.2.ebuild b/media-sound/mpg123/mpg123-1.12.2.ebuild
new file mode 100644
index 000000000000..feff2f624ace
--- /dev/null
+++ b/media-sound/mpg123/mpg123-1.12.2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/mpg123-1.12.2.ebuild,v 1.1 2010/06/21 11:25:41 chainsaw Exp $
+
+EAPI=2
+inherit toolchain-funcs
+
+DESCRIPTION="a realtime MPEG 1.0/2.0/2.5 audio player for layers 1, 2 and 3"
+HOMEPAGE="http://www.mpg123.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
+	http://www.mpg123.org/download/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="3dnow 3dnowext alsa altivec ipv6 jack mmx nas oss portaudio pulseaudio sdl sse"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	jack? ( media-sound/jack-audio-connection-kit )
+	nas? ( media-libs/nas )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	sdl? ( media-libs/libsdl )
+	sys-devel/libtool"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+src_configure() {
+	local _audio=dummy
+	local _output=dummy
+	local _cpu=generic_fpu
+
+	for flag in nas portaudio sdl oss jack alsa pulseaudio; do
+		if use ${flag}; then
+			_audio="${_audio} ${flag/pulseaudio/pulse}"
+			_output=${flag/pulseaudio/pulse}
+		fi
+	done
+
+	use altivec && _cpu=altivec
+
+	if [[ $(tc-arch) == amd64 ]]; then
+		use sse && _cpu=x86-64
+	else
+		use mmx && _cpu=mmx
+		use 3dnow && _cpu=3dnow
+		use sse && _cpu=x86
+		use 3dnowext && _cpu=x86
+	fi
+
+	econf \
+		--disable-dependency-tracking \
+		--with-optimization=0 \
+		--with-audio="${_audio}" \
+		--with-default-audio=${_output} \
+		--with-cpu=${_cpu} \
+		--enable-network \
+		$(use_enable ipv6)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS ChangeLog NEWS* README
+}