version bump

(Portage version: 2.2.8/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

2 files changed, 66 insertions, 2 deletions

diff --git a/media-sound/qsynth/ChangeLog b/media-sound/qsynth/ChangeLog
index b1a2217e6d75..4c5f5c5d37c4 100644
--- a/media-sound/qsynth/ChangeLog
+++ b/media-sound/qsynth/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/qsynth
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/ChangeLog,v 1.59 2013/04/17 18:34:24 aballier Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/ChangeLog,v 1.60 2014/01/18 12:35:37 aballier Exp $
+
+*qsynth-0.3.8 (18 Jan 2014)
+
+  18 Jan 2014; Alexis Ballier <aballier@gentoo.org> +qsynth-0.3.8.ebuild:
+  version bump
 
 *qsynth-0.3.7 (17 Apr 2013)
 
diff --git a/media-sound/qsynth/qsynth-0.3.8.ebuild b/media-sound/qsynth/qsynth-0.3.8.ebuild
new file mode 100644
index 000000000000..5b9372dd18e9
--- /dev/null
+++ b/media-sound/qsynth/qsynth-0.3.8.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/qsynth-0.3.8.ebuild,v 1.1 2014/01/18 12:35:37 aballier Exp $
+
+EAPI=4
+LANGS="cs de es fr ru sr"
+
+inherit qt4-r2 eutils
+
+DESCRIPTION="A Qt application to control FluidSynth"
+HOMEPAGE="http://qsynth.sourceforge.net/"
+SRC_URI="mirror://sourceforge/qsynth/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="debug jack alsa pulseaudio"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+DEPEND=">=dev-qt/qtcore-4.2:4
+	>=dev-qt/qtgui-4.2:4
+	>=media-sound/fluidsynth-1.0.7a[jack?,alsa?,pulseaudio?]
+	x11-libs/libX11
+	!pulseaudio? ( !jack? ( !alsa? ( >=media-sound/fluidsynth-1.0.7a[oss] ) ) )"
+RDEPEND="${DEPEND}"
+
+DOCS="AUTHORS ChangeLog README TODO TRANSLATORS"
+
+src_configure() {
+	econf \
+		$(use_enable debug)
+
+	eqmake4 "${PN}.pro" -o "${PN}.mak"
+}
+
+src_compile() {
+	lupdate "${PN}.pro" || die "lupdate failed"
+	qt4-r2_src_compile
+}
+
+src_install () {
+	qt4-r2_src_install
+
+	# The desktop file is invalid, and we also change the command
+	# depending on useflags
+	rm -rf "${D}/usr/share/applications/qsynth.desktop"
+
+	local cmd
+	if use jack; then
+		cmd="qsynth"
+	elif use pulseaudio; then
+		cmd="qsynth -a pulseaudio"
+	elif use alsa; then
+		cmd="qsynth -a alsa"
+	else
+		cmd="qsynth -a oss"
+	fi
+
+	make_desktop_entry "${cmd}" Qsynth qsynth
+}