Version bump.

(Portage version: 2.2_rc33/cvs/Linux x86_64)

1 files changed, 51 insertions, 0 deletions

diff --git a/media-sound/sooperlooper/sooperlooper-1.6.13_p2.ebuild b/media-sound/sooperlooper/sooperlooper-1.6.13_p2.ebuild
new file mode 100644
index 000000000000..5078753b9e55
--- /dev/null
+++ b/media-sound/sooperlooper/sooperlooper-1.6.13_p2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/sooperlooper/sooperlooper-1.6.13_p2.ebuild,v 1.1 2009/07/19 12:43:13 ssuominen Exp $
+
+EAPI=2
+inherit autotools eutils wxwidgets
+
+DESCRIPTION="Live looping sampler with immediate loop recording"
+HOMEPAGE="http://essej.net/sooperlooper/index.html"
+SRC_URI="http://essej.net/sooperlooper/${P/_p/-}.tar.gz
+	mirror://gentoo/${PN}-1.6.5-m4.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+RDEPEND="media-sound/jack-audio-connection-kit
+	x11-libs/wxGTK:2.8
+	media-libs/liblo
+	dev-libs/libsigc++:1.2
+	media-libs/libsndfile
+	media-libs/libsamplerate
+	dev-libs/libxml2
+	media-libs/rubberband
+	sci-libs/fftw:3.0"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S=${WORKDIR}/${P/_p*}
+
+src_prepare() {
+	cp -rf "${WORKDIR}"/aclocal "${S}" || die "copying aclocal failed"
+	epatch "${FILESDIR}"/${PN}-1.6.5-cxxflags.patch
+	AT_M4DIR="${S}/aclocal" eautoreconf
+}
+
+src_configure() {
+	WX_GTK_VER="2.8"
+	need-wxwidgets unicode
+
+	econf \
+		--disable-dependency-tracking \
+		--disable-optimize \
+		--with-wxconfig-path="${WX_CONFIG}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc OSC README
+}