Version bump (bug #533716). Conversion to distutils-r1.eclass and readme.gentoo.eclass.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 0x0F9C590B7FF324F6!)

2 files changed, 62 insertions, 2 deletions

diff --git a/media-sound/picard/ChangeLog b/media-sound/picard/ChangeLog
index f0343337fc97..af06dff99547 100644
--- a/media-sound/picard/ChangeLog
+++ b/media-sound/picard/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/picard
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/picard/ChangeLog,v 1.47 2014/12/13 06:43:36 yngwin Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/picard/ChangeLog,v 1.48 2015/01/02 05:21:40 yngwin Exp $
+
+*picard-1.3.1 (02 Jan 2015)
+
+  02 Jan 2015; Ben de Groot <yngwin@gentoo.org> +picard-1.3.1.ebuild:
+  Version bump (bug #533716). Conversion to distutils-r1.eclass and
+  readme.gentoo.eclass.
 
 *picard-1.3 (13 Dec 2014)
 
diff --git a/media-sound/picard/picard-1.3.1.ebuild b/media-sound/picard/picard-1.3.1.ebuild
new file mode 100644
index 000000000000..82fa9ef1cc23
--- /dev/null
+++ b/media-sound/picard/picard-1.3.1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/picard/picard-1.3.1.ebuild,v 1.1 2015/01/02 05:21:40 yngwin Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_SINGLE_IMPL=1
+DISABLE_AUTOFORMATTING=true
+inherit eutils distutils-r1 readme.gentoo
+
+DESCRIPTION="A cross-platform music tagger"
+HOMEPAGE="http://picard.musicbrainz.org/"
+SRC_URI="http://ftp.musicbrainz.org/pub/musicbrainz/picard/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="+acoustid +cdda nls"
+
+DEPEND="dev-python/PyQt4[X,${PYTHON_USEDEP}]
+	media-libs/mutagen
+	acoustid? ( >=media-libs/chromaprint-1.0[tools] )
+	cdda? ( >=media-libs/libdiscid-0.1.1 )"
+RDEPEND="${DEPEND}"
+
+RESTRICT="test" # doesn't work with ebuilds
+S=${WORKDIR}/${PN}-release-${PV}
+DOCS="AUTHORS.txt NEWS.txt"
+
+DOC_CONTENTS="If you are upgrading Picard and it does not start,
+try removing Picard's settings:
+    rm ~/.config/MusicBrainz/Picard.conf
+
+You should set the environment variable BROWSER to something like
+    firefox '%s' &
+to let python know which browser to use."
+
+src_compile() {
+	distutils-r1_src_compile $(use nls || echo "--disable-locales")
+}
+
+src_install() {
+	distutils-r1_src_install --disable-autoupdate --skip-build \
+		$(use nls || echo "--disable-locales")
+
+	doicon picard.ico
+	domenu picard.desktop
+	readme.gentoo_create_doc
+}
+
+pkg_postinstall() {
+	default
+	readme.gentoo_pkg_postinst
+}