Add a snapshot of amarok from SVN to avoid having to backport all the fixes.

(Portage version: 2.1.2.9)

3 files changed, 110 insertions, 1 deletions

diff --git a/media-sound/amarok/ChangeLog b/media-sound/amarok/ChangeLog
index f86888e1dc48..c032e549840f 100644
--- a/media-sound/amarok/ChangeLog
+++ b/media-sound/amarok/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/amarok
 # Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.216 2007/06/07 19:59:08 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.217 2007/06/08 14:01:18 flameeyes Exp $
+
+*amarok-1.4.6_pre20070608 (08 Jun 2007)
+
+  08 Jun 2007; Diego Pettenò <flameeyes@gentoo.org>
+  +amarok-1.4.6_pre20070608.ebuild:
+  Add a snapshot of amarok from SVN to avoid having to backport all the fixes.
 
 *amarok-1.4.5-r2 (07 Jun 2007)
 
diff --git a/media-sound/amarok/amarok-1.4.6_pre20070608.ebuild b/media-sound/amarok/amarok-1.4.6_pre20070608.ebuild
new file mode 100644
index 000000000000..f2d0266fcff3
--- /dev/null
+++ b/media-sound/amarok/amarok-1.4.6_pre20070608.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-1.4.6_pre20070608.ebuild,v 1.1 2007/06/08 14:01:18 flameeyes Exp $
+
+LANGS="af ar az be bg bn br ca cs cy da de el en_GB eo es et eu fa fi
+fr ga gl he hi hu id is it ja km ko ku lo lt mk ms nb nds nl nn pa pl
+pt pt_BR ro ru rw se sk sl sq sr sr@Latn ss sv ta tg th tr uk uz zh_CN
+zh_TW"
+LANGS_DOC="da de es et fr it nl pl pt pt_BR ru sv"
+
+USE_KEG_PACKAGING=1
+
+inherit kde eutils flag-o-matic
+
+PKG_SUFFIX=""
+
+if [[ ${P/_pre} == ${P} ]]; then
+	MY_P="${P/_/-}"
+	S="${WORKDIR}/${P/_/-}"
+
+	SRC_URI="mirror://kde/stable/amarok/${PV}/src/${MY_P}.tar.bz2"
+else
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+fi
+
+DESCRIPTION="Advanced audio player based on KDE framework."
+HOMEPAGE="http://amarok.kde.org/"
+
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="aac kde mysql noamazon opengl postgres
+visualization ipod ifp real njb mtp musicbrainz daap
+python"
+# kde: enables compilation of the konqueror sidebar plugin
+
+RDEPEND="kde? ( || ( kde-base/konqueror kde-base/kdebase ) )
+	>=media-libs/xine-lib-1.1.2_pre20060328-r8
+	>=media-libs/taglib-1.4
+	mysql? ( >=virtual/mysql-4.0 )
+	postgres? ( dev-db/libpq )
+	opengl? ( virtual/opengl )
+	visualization? ( media-libs/libsdl
+					 =media-plugins/libvisual-plugins-0.4* )
+	ipod? ( >=media-libs/libgpod-0.4.2 )
+	aac? ( media-libs/libmp4v2 )
+	ifp? ( media-libs/libifp )
+	real? ( media-video/realplayer )
+	njb? ( >=media-libs/libnjb-2.2.4 )
+	mtp? ( >=media-libs/libmtp-0.1.1 )
+	musicbrainz? ( media-libs/tunepimp )
+	=dev-lang/ruby-1.8*"
+
+DEPEND="${RDEPEND}"
+
+RDEPEND="${RDEPEND}
+	app-arch/unzip
+	python? ( dev-python/PyQt )
+	daap? ( www-servers/mongrel )"
+
+need-kde 3.3
+
+src_compile() {
+	# Extra, unsupported engines are forcefully disabled.
+	local myconf="$(use_enable mysql) $(use_enable postgres postgresql)
+				  $(use_with opengl) --without-xmms
+				  $(use_with visualization libvisual)
+				  $(use_enable !noamazon amazon)
+				  $(use_with ipod libgpod)
+				  $(use_with aac mp4v2)
+				  $(use_with ifp)
+				  $(use_with real helix)
+				  $(use_with njb libnjb)
+				  $(use_with mtp libmtp)
+				  $(use_with musicbrainz)
+				  $(use_with daap)
+				  --with-xine
+				  --without-mas
+				  --without-nmm"
+
+	kde_src_compile
+}
+
+src_install() {
+	kde_src_install
+
+	# As much as I respect Ian, I'd rather leave Amarok to use mongrel
+	# from Portage, for security and policy reasons.
+	rm -rf "${D}"/usr/share/apps/amarok/ruby_lib/rbconfig \
+		"${D}"/usr/share/apps/amarok/ruby_lib/mongrel* \
+		"${D}"/usr/share/apps/amarok/ruby_lib/rubygems* \
+		"${D}"/usr/share/apps/amarok/ruby_lib/gem* \
+		"${D}"/usr/$(get_libdir)/ruby_lib
+
+	if ! use python; then
+		rm -r "${D}"/usr/share/apps/amarok/scripts/webcontrol \
+			|| die "Unable to remove webcontrol."
+	fi
+}
diff --git a/media-sound/amarok/files/digest-amarok-1.4.6_pre20070608 b/media-sound/amarok/files/digest-amarok-1.4.6_pre20070608
new file mode 100644
index 000000000000..20f746a6fa76
--- /dev/null
+++ b/media-sound/amarok/files/digest-amarok-1.4.6_pre20070608
@@ -0,0 +1,3 @@
+MD5 4da98b7cfeeb7c34f76146e89f76f7c4 amarok-1.4.6_pre20070608.tar.bz2 17956550
+RMD160 06a9296d548fe0d97dafc657ecc39125e8b4654a amarok-1.4.6_pre20070608.tar.bz2 17956550
+SHA256 7dbf7c67936b232c0962e93c3de546559bb63ab1d02c70e42cb07ba064451030 amarok-1.4.6_pre20070608.tar.bz2 17956550