Use python-single-r1.eclass instead of python.eclass. Remove deprecated optional gnome-vfs-python dependency. Fix MimeType in .desktop file.

(Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

2 files changed, 30 insertions, 32 deletions

diff --git a/media-sound/listen/ChangeLog b/media-sound/listen/ChangeLog
index 7b8cc026e037..587423d5c727 100644
--- a/media-sound/listen/ChangeLog
+++ b/media-sound/listen/ChangeLog
@@ -1,6 +1,10 @@
 # ChangeLog for media-sound/listen
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/listen/ChangeLog,v 1.32 2012/05/05 09:02:05 mgorny Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/listen/ChangeLog,v 1.33 2013/05/28 04:53:29 ssuominen Exp $
+
+  28 May 2013; Samuli Suominen <ssuominen@gentoo.org> listen-0.6.5-r1.ebuild:
+  Use python-single-r1.eclass instead of python.eclass. Remove deprecated
+  optional gnome-vfs-python dependency. Fix MimeType in .desktop file.
 
   05 May 2012; Michał Górny <mgorny@gentoo.org> listen-0.6.5-r1.ebuild:
   dev-util/pkgconfig -> virtual/pkgconfig
diff --git a/media-sound/listen/listen-0.6.5-r1.ebuild b/media-sound/listen/listen-0.6.5-r1.ebuild
index f8263d35cd54..77f5e29d8b9c 100644
--- a/media-sound/listen/listen-0.6.5-r1.ebuild
+++ b/media-sound/listen/listen-0.6.5-r1.ebuild
@@ -1,65 +1,59 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/listen/listen-0.6.5-r1.ebuild,v 1.2 2012/05/05 09:02:05 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/listen/listen-0.6.5-r1.ebuild,v 1.3 2013/05/28 04:53:29 ssuominen Exp $
 
-EAPI=3
-PYTHON_DEPEND="2:2.6"
-inherit eutils multilib python
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+inherit eutils multilib python-single-r1
 
 DESCRIPTION="A music management and playback for GTK+ based desktops"
 HOMEPAGE="http://www.listen-project.org/"
-SRC_URI="http://download.listen-project.org/0.6/${P}.tar.gz"
+SRC_URI="http://download.listen-project.org/${PV%.*}/${P}.tar.gz"
 
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
-IUSE="cdda gnome"
-
-RDEPEND="dev-python/dbus-python
-	dev-python/gst-python:0.10
-	>=dev-python/pygtk-2.8:2
-	dev-python/pyinotify
-	|| ( dev-python/python-xlib dev-python/egg-python )
+IUSE="cdda"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/gst-python:0.10[${PYTHON_USEDEP}]
+	>=dev-python/pygtk-2.8:2[${PYTHON_USEDEP}]
+	dev-python/pyinotify[${PYTHON_USEDEP}]
+	|| ( dev-python/python-xlib[${PYTHON_USEDEP}] dev-python/egg-python[${PYTHON_USEDEP}] )
 	dev-python/pywebkitgtk
-	dev-python/pyxdg
+	dev-python/pyxdg[${PYTHON_USEDEP}]
 	media-libs/libgpod[python]
-	media-libs/mutagen
+	media-libs/mutagen[${PYTHON_USEDEP}]
 	media-plugins/gst-plugins-meta:0.10
 	x11-libs/libnotify
-	cdda? ( dev-python/python-musicbrainz )
-	gnome? ( dev-python/gnome-vfs-python )"
+	cdda? ( dev-python/python-musicbrainz[${PYTHON_USEDEP}] )"
 DEPEND="${RDEPEND}
 	app-text/docbook2X
 	dev-util/intltool
-	virtual/pkgconfig
 	sys-devel/gettext
+	virtual/pkgconfig
 	!media-radio/ax25-apps"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
 pkg_setup() {
-	python_set_active_version 2
-	python_pkg_setup
+	python-single-r1_pkg_setup
 }
 
 src_prepare() {
 	epatch "${FILESDIR}"/${P}-Makefile.patch
+	sed -i -e 's:audip/mp3:audio/mp3:' misc/listen.desktop.in || die
 }
 
 src_compile() {
-	CHECK_DEPENDS=0 emake PYTHON="$(PYTHON)" || die
+	CHECK_DEPENDS=0 emake PYTHON="${EPYTHON}"
 }
 
 src_test() { :; } #324719
 
 src_install() {
-	DESTDIR="${D}" LIBDIR="/usr/$(get_libdir)" emake \
-		install || die
+	DESTDIR="${D}" LIBDIR="/usr/$(get_libdir)" emake install
 	dodoc README
-}
-
-pkg_postinst() {
-	python_mod_optimize /usr/$(get_libdir)/${PN}
-}
 
-pkg_postrm() {
-	python_mod_cleanup /usr/$(get_libdir)/${PN}
+	python_optimize "${ED}"/usr/$(get_libdir)/${PN}
 }