Version bump.

(Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

3 files changed, 86 insertions, 1 deletions

diff --git a/media-video/gnome-mplayer/ChangeLog b/media-video/gnome-mplayer/ChangeLog
index 7c0ede3a8b05..1622eb4d2e69 100644
--- a/media-video/gnome-mplayer/ChangeLog
+++ b/media-video/gnome-mplayer/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/gnome-mplayer
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/ChangeLog,v 1.84 2013/02/14 18:38:40 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/ChangeLog,v 1.85 2013/06/03 07:13:20 ssuominen Exp $
+
+*gnome-mplayer-1.0.8 (03 Jun 2013)
+
+  03 Jun 2013; Samuli Suominen <ssuominen@gentoo.org>
+  +gnome-mplayer-1.0.8.ebuild, metadata.xml:
+  Version bump.
 
   14 Feb 2013; Samuli Suominen <ssuominen@gentoo.org>
   -gnome-mplayer-1.0.6.ebuild:
diff --git a/media-video/gnome-mplayer/gnome-mplayer-1.0.8.ebuild b/media-video/gnome-mplayer/gnome-mplayer-1.0.8.ebuild
new file mode 100644
index 000000000000..82110ef8b8be
--- /dev/null
+++ b/media-video/gnome-mplayer/gnome-mplayer-1.0.8.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/gnome-mplayer-1.0.8.ebuild,v 1.1 2013/06/03 07:13:20 ssuominen Exp $
+
+EAPI=5
+inherit fdo-mime gnome2-utils
+
+DESCRIPTION="A GTK+ interface to MPlayer"
+HOMEPAGE="http://code.google.com/p/gnome-mplayer/"
+SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="alsa +dbus +dconf gda gnome ipod libnotify musicbrainz pulseaudio"
+
+COMMON_DEPEND=">=dev-libs/glib-2.30
+	>=media-libs/gmtk-${PV}[dconf=]
+	>=x11-libs/gtk+-3.2:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	alsa? ( media-libs/alsa-lib )
+	dbus? ( >=dev-libs/dbus-glib-0.100 )
+	gda? ( gnome-extra/libgda:5 )
+	gnome? ( gnome-base/nautilus )
+	ipod? ( >=media-libs/libgpod-0.7 )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	musicbrainz? (
+		media-libs/musicbrainz:3
+		net-misc/curl
+		)
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.14 )"
+RDEPEND="${COMMON_DEPEND}
+	x11-themes/gnome-icon-theme-symbolic
+	|| ( >=media-video/mplayer-1.0_rc4_p20100101[libass] media-video/mplayer2[libass] )"
+DEPEND="${COMMON_DEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+DOCS="ChangeLog README DOCS/*.txt DOCS/tech/*.txt"
+
+src_configure() {
+	econf \
+		--enable-gtk3 \
+		$(use_enable gnome nautilus) \
+		--with-gio \
+		$(use_with dbus) \
+		$(use_with gda libgda) \
+		$(use_with alsa) \
+		$(use_with pulseaudio) \
+		$(use_with libnotify) \
+		$(use_with ipod libgpod) \
+		$(use_with musicbrainz libmusicbrainz3)
+}
+
+src_install() {
+	default
+	rm -rf "${ED}"/usr/share/doc/${PN}
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}
diff --git a/media-video/gnome-mplayer/metadata.xml b/media-video/gnome-mplayer/metadata.xml
index 5e8e19936618..e77a792b8a4b 100644
--- a/media-video/gnome-mplayer/metadata.xml
+++ b/media-video/gnome-mplayer/metadata.xml
@@ -7,5 +7,6 @@
   </maintainer>
   <use>
     <flag name='dconf'>Enable support for <pkg>gnome-base/dconf</pkg></flag>
+    <flag name='gda'>Enable support for <pkg>gnome-extra/libgda</pkg></flag>
   </use>
 </pkgmetadata>