Revision bump and removed previous 1.x versions. Close bug #110997 (modular x support, it's modular friendly saved ffmpeg that is still unfriendly), bug #111290 (missing libxml2 dependency), bug #112995 (long path crashes), bug #112382 (lzo-2 support).

(Portage version: 2.0.53)

1 files changed, 163 insertions, 0 deletions

diff --git a/media-video/transcode/transcode-1.0.2-r1.ebuild b/media-video/transcode/transcode-1.0.2-r1.ebuild
new file mode 100644
index 000000000000..1c0c29affb6e
--- /dev/null
+++ b/media-video/transcode/transcode-1.0.2-r1.ebuild
@@ -0,0 +1,163 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/transcode/transcode-1.0.2-r1.ebuild,v 1.1 2005/12/10 16:06:44 flameeyes Exp $
+
+inherit libtool flag-o-matic eutils multilib autotools
+
+MY_P="${P/_/}"
+S=${WORKDIR}/${MY_P}
+DESCRIPTION="video stream processing tool"
+HOMEPAGE="http://www.transcoding.org/cgi-bin/transcode"
+SRC_URI="mirror://transcode/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="X 3dnow a52 altivec dv dvdread mp3 fame truetype gtk imagemagick jpeg
+lzo mjpeg mpeg mmx network ogg vorbis pvm quicktime sdl sse sse2 theora v4l
+xvid xml2 ffmpeg"
+
+RDEPEND="a52? ( >=media-libs/a52dec-0.7.4 )
+	dv? ( >=media-libs/libdv-0.99 )
+	dvdread? ( >=media-libs/libdvdread-0.9.0 )
+	xvid? ( >=media-libs/xvid-1.0.2 )
+	mjpeg? ( >=media-video/mjpegtools-1.6.2-r3 )
+	lzo? ( >=dev-libs/lzo-2 )
+	fame? ( >=media-libs/libfame-0.9.1 )
+	imagemagick? ( >=media-gfx/imagemagick-5.5.6.0 )
+	media-libs/netpbm
+	media-libs/libexif
+	mpeg? ( media-libs/libmpeg3 )
+	mp3? ( >=media-sound/lame-3.93 )
+	sdl? ( media-libs/libsdl )
+	quicktime? ( >=media-libs/libquicktime-0.9.3 )
+	vorbis? ( media-libs/libvorbis )
+	ogg? ( media-libs/libogg )
+	theora? ( media-libs/libtheora )
+	jpeg? ( media-libs/jpeg )
+	gtk? ( =x11-libs/gtk+-1.2* )
+	truetype? ( >=media-libs/freetype-2 )
+	pvm? ( >=sys-cluster/pvm-3.4 )
+	ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20050226-r3 )
+	|| ( sys-libs/glibc dev-libs/libiconv )
+	>=media-libs/libmpeg2-0.4.0b
+	xml2? ( dev-libs/libxml2 )
+	X? ( || ( (
+			x11-libs/libX11
+			x11-libs/libXext
+			x11-libs/libXpm
+			x11-libs/libXt
+			x11-libs/libICE
+			x11-libs/libSM
+			x11-libs/libXaw
+			x11-libs/libXv )
+		virtual/x11 ) )
+"
+
+DEPEND="${RDEPEND}
+	v4l? ( >=sys-kernel/linux-headers-2.6.11 )
+	X? ( || ( ( x11-base/xorg-server
+			x11-libs/libX11
+			x11-libs/libXt
+			x11-libs/libXaw
+			x11-libs/libXv
+			x11-proto/xproto
+			x11-proto/xextproto )
+		virtual/x11 ) )
+	sys-devel/autoconf
+	sys-devel/automake
+	sys-devel/libtool"
+
+pkg_setup() {
+	if has_version x11-base/xorg-x11 && ! built_with_use x11-base/xorg-x11 xv; then
+		die "You need xorg-x11 emerged with xv support to compile transcode."
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}
+
+	sed -i -e "s:\$(datadir)/doc/transcode:\$(datadir)/doc/${PF}:" \
+		${S}/docs/Makefile.am ${S}/docs/html/Makefile.am
+
+	epatch "${FILESDIR}/${P}-bigdir.patch"
+	epatch "${FILESDIR}/${P}-lzo2.patch"
+
+	eautoreconf
+	elibtoolize
+}
+
+src_compile() {
+	filter-flags -maltivec -mabi=altivec -momit-leaf-frame-pointer
+	use ppc && append-flags -U__ALTIVEC__
+
+	if use pvm; then
+		if use sparc; then
+			myconf="${myconf} --enable-pvm3 \
+				--with-pvm3-lib=${PVM_ROOT}/lib/LINUXSPARC \
+				--with-pvm3-include=${PVM_ROOT}/include"
+		else
+			myconf="${myconf} --enable-pvm3 \
+				--with-pvm3-lib=${PVM_ROOT}/lib/LINUX \
+				--with-pvm3-include=${PVM_ROOT}/include"
+		fi
+	fi
+
+	use xvid \
+		&& myconf="${myconf} --with-default-xvid=xvid4"
+
+	# Hardenable SIMD extensions on amd64
+	if use amd64; then
+		myconf="${myconf} --enable-mmx --enable-3dnow \
+				--enable-sse --enable-sse2"
+	elif use x86; then
+		myconf="${myconf} $(use_enable mmx) \
+				$(use_enable 3dnow) \
+				$(use_enable sse) \
+				$(use_enable sse2)"
+	fi
+
+	append-flags -DDCT_YUV_PRECISION=1
+	econf \
+		$(use_enable altivec) \
+		$(use_enable network netstream) \
+		$(use_enable truetype freetype2) \
+		$(use_enable v4l) \
+		$(use_enable mp3 lame) \
+		$(use_enable ogg) \
+		$(use_enable vorbis) \
+		$(use_enable theora) \
+		$(use_enable dvdread libdvdread) \
+		$(use_enable dv libdv) \
+		$(use_enable quicktime libquicktime) \
+		$(use_enable lzo) \
+		$(use_enable a52) \
+		$(use_enable mpeg libmpeg3) \
+		$(use_enable xml2 libxml2) \
+		$(use_enable mjpeg mjpegtools) \
+		$(use_enable sdl) \
+		$(use_enable gtk) \
+		$(use_enable fame libfame) \
+		$(use_enable imagemagick) \
+		$(use_enable jpeg libjpeg) \
+		--with-mod-path=/usr/$(get_libdir)/transcode \
+		$(use_with X x) \
+		$(use_with ffmpeg libpostproc-builddir "${ROOT}/usr/$(get_libdir)") \
+		${myconf} \
+		--with-lzo-includes=/usr/include/lzo \
+		--disable-avifile \
+		|| die
+
+	emake all || die
+
+	if use pvm; then
+		sed -i -e "s:\${exec_prefix}/bin/pvmgs:\$(DESTDIR)/\${exec_prefix}/bin/pvmgs:" ${S}/pvm3/Makefile || die
+	fi
+}
+
+src_install () {
+	make DESTDIR=${D} install || die
+
+	dodoc AUTHORS ChangeLog README TODO
+}