media-video/avidemux version bump to 2.4.1

(Portage version: 2.1.4.4)

3 files changed, 125 insertions, 1 deletions

diff --git a/media-video/avidemux/ChangeLog b/media-video/avidemux/ChangeLog
index 9488b5d09789..167db31b1dbb 100644
--- a/media-video/avidemux/ChangeLog
+++ b/media-video/avidemux/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/avidemux
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/ChangeLog,v 1.123 2008/02/15 15:39:00 drac Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/ChangeLog,v 1.124 2008/02/17 16:10:14 yngwin Exp $
+
+*avidemux-2.4.1 (17 Feb 2008)
+
+  17 Feb 2008; Ben de Groot (yngwin) <ben@berkano.net> metadata.xml,
+  +avidemux-2.4.1.ebuild:
+  Version bump. Should fix #207326.
 
   15 Feb 2008; Samuli Suominen <drac@gentoo.org> avidemux-2.4.ebuild:
   Move fontconfig behind truetype flag to match other ebuilds in tree.
diff --git a/media-video/avidemux/avidemux-2.4.1.ebuild b/media-video/avidemux/avidemux-2.4.1.ebuild
new file mode 100644
index 000000000000..a4773d804669
--- /dev/null
+++ b/media-video/avidemux/avidemux-2.4.1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/avidemux-2.4.1.ebuild,v 1.1 2008/02/17 16:10:14 yngwin Exp $
+
+inherit cmake-utils eutils flag-o-matic
+
+MY_P=${PN}_${PV}
+
+DESCRIPTION="Video editor designed for simple cutting, filtering and encoding tasks."
+HOMEPAGE="http://fixounet.free.fr/avidemux"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="2"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="aac aften alsa amrnb arts dts encode esd jack lame libsamplerate
+truetype vorbis x264 xv xvid gtk qt4"
+
+RDEPEND="dev-libs/libxml2
+	media-libs/libpng
+	media-libs/libsdl
+	>=dev-libs/glib-2
+	aac? ( media-libs/faad2 )
+	aften? ( media-libs/aften )
+	alsa? ( media-libs/alsa-lib )
+	amrnb? ( media-libs/amrnb )
+	arts? ( kde-base/arts )
+	dts? ( media-libs/libdca )
+	encode? (
+		aac? ( media-libs/faac )
+		lame? ( media-sound/lame )
+		)
+	esd? ( media-sound/esound )
+	jack? ( media-sound/jack-audio-connection-kit )
+	libsamplerate? ( media-libs/libsamplerate )
+	truetype? ( media-libs/freetype
+		media-libs/fontconfig )
+	vorbis? ( media-libs/libvorbis )
+	x264? ( media-libs/x264-svn )
+	xv? ( x11-libs/libXv )
+	xvid? ( media-libs/xvid )
+	gtk? ( >=x11-libs/gtk+-2
+		x11-libs/libX11 )
+	qt4? ( >=x11-libs/qt-4.3
+		x11-libs/libX11 )"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	dev-util/pkgconfig
+	>=dev-util/cmake-2.4.4"
+
+S=${WORKDIR}/${MY_P}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	# TODO. Needs to be reported upstream.
+	epatch "${FILESDIR}"/${PN}-2.4-libdca.patch
+	epatch "${FILESDIR}"/${PN}-2.4-i18n.patch
+}
+
+src_compile() {
+	# -O3 corrups names in the Qt4 filters dialog -yngwin
+	replace-flags -O3 -O2
+
+	# Commented out options cause compilation errors, some
+	# might need -Wl,--as-needed in LDFLAGS and all USE
+	# flags disabled for reproducing. -drac
+	# TODO. Needs to be fixed, or reported upstream.
+
+	local mycmakeargs
+
+	# ConfigureChecks.cmake
+	use alsa || mycmakeargs="${mycmakeargs} -DNO_ALSA=1"
+	#use oss || mycmakeargs="${mycmakeargs} -DNO_OSS=1"
+	#use nls || mycmakeargs="${mycmakeargs} -DNO_NLS=1"
+	#use sdl || mycmakeargs="${mycmakeargs} -DNO_SDL=1"
+
+	# ConfigureChecks.cmake -> ADM_CHECK_HL -> cmake/adm_checkHeaderLib.cmake
+	use truetype || mycmakeargs="${mycmakeargs} -DNO_FontConfig=1"
+	use xv || mycmakeargs="${mycmakeargs} -DNO_Xvideo=1"
+	use esd || mycmakeargs="${mycmakeargs} -DNO_Esd=1"
+	use jack || mycmakeargs="${mycmakeargs} -DNO_Jack=1"
+	use aften || mycmakeargs="${mycmakeargs} -DNO_Aften=1"
+	use libsamplerate || mycmakeargs="${mycmakeargs} -DNO_libsamplerate=1"
+	use encode || mycmakeargs="${mycmakeargs} -DNO_Lame=1 -DNO_FAAC=1"
+	use xvid || mycmakeargs="${mycmakeargs} -DNO_Xvid=1"
+	use amrnb || mycmakeargs="${mycmakeargs} -DNO_AMRNB=1"
+	use dts || mycmakeargs="${mycmakeargs} -DNO_libdca=1"
+	use x264 || mycmakeargs="${mycmakeargs} -DNO_x264=1"
+	use aac || mycmakeargs="${mycmakeargs} -DNO_FAAD=1 -DNO_NeAAC=1"
+	use vorbis || mycmakeargs="${mycmakeargs} -DNO_Vorbis=1"
+	#use png || mycmakeargs="${mycmakeargs} -DNO_libPNG=1"
+
+	# ConfigureChecks.cmake -> cmake/FindArts.cmake
+	use arts || mycmakeargs="${mycmakeargs} -DNO_ARTS=1"
+
+	# CMakeLists.txt
+	use truetype || mycmakeargs="${mycmakeargs} -DNO_FREETYPE=1"
+	use gtk || mycmakeargs="${mycmakeargs} -DNO_GTK=1"
+	use qt4 || mycmakeargs="${mycmakeargs} -DNO_QT4=1"
+
+	cmake-utils_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+	dodoc AUTHORS
+	doicon avidemux_icon.png
+
+	use gtk && make_desktop_entry avidemux2_gtk "Avidemux GTK" \
+		avidemux_icon "AudioVideo;GTK;"
+	use qt4 && make_desktop_entry avidemux2_qt4 "Avidemux Qt" \
+		avidemux_icon "AudioVideo;Qt;"
+}
diff --git a/media-video/avidemux/metadata.xml b/media-video/avidemux/metadata.xml
index 92e4dbc04f50..2066d203ad2d 100644
--- a/media-video/avidemux/metadata.xml
+++ b/media-video/avidemux/metadata.xml
@@ -2,4 +2,8 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 	<herd>video</herd>
+	<maintainer>
+		<email>yngwin@gentoo.org</email>
+		<name>Ben de Groot</name>
+	</maintainer>
 </pkgmetadata>