Respect LDFLAGS (bug #336231). Do not hardwire CFLAGS. Do not install LICENSE. Remove unneeded cd. Respect CC.

(Portage version: 2.2_rc77/cvs/Linux i686)

2 files changed, 51 insertions, 2 deletions

diff --git a/net-analyzer/siphon/ChangeLog b/net-analyzer/siphon/ChangeLog
index 05312461a7ef..dc4a8b612717 100644
--- a/net-analyzer/siphon/ChangeLog
+++ b/net-analyzer/siphon/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-analyzer/siphon
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/siphon/ChangeLog,v 1.14 2009/09/23 18:24:00 patrick Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/siphon/ChangeLog,v 1.15 2010/09/07 16:33:59 jer Exp $
+
+*siphon-666-r1 (07 Sep 2010)
+
+  07 Sep 2010; Jeroen Roovers <jer@gentoo.org> +siphon-666-r1.ebuild:
+  Respect LDFLAGS (bug #336231). Do not hardwire CFLAGS. Do not install
+  LICENSE. Remove unneeded cd. Respect CC. 
 
   23 Sep 2009; Patrick Lauer <patrick@gentoo.org> siphon-666.ebuild:
   Remove virtual/libc
diff --git a/net-analyzer/siphon/siphon-666-r1.ebuild b/net-analyzer/siphon/siphon-666-r1.ebuild
new file mode 100644
index 000000000000..5ad9f7abab42
--- /dev/null
+++ b/net-analyzer/siphon/siphon-666-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/siphon/siphon-666-r1.ebuild,v 1.1 2010/09/07 16:33:59 jer Exp $
+
+EAPI="2"
+
+inherit toolchain-funcs
+
+MY_P=${PN}-v.${PV}
+
+DESCRIPTION="A portable passive network mapping suite"
+SRC_URI="http://siphon.datanerds.net/${MY_P}.tar.gz"
+HOMEPAGE="http://siphon.datanerds.net/"
+
+SLOT="0"
+LICENSE="as-is"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+
+DEPEND="net-libs/libpcap"
+IUSE=""
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	sed -i log.c \
+		-e 's:osprints\.conf:/etc/osprints.conf:' \
+		|| die "sed log.c"
+	sed -i Makefile \
+		-e '/^CFLAGS/s:=.*:+= -pthread -Wall -I.:g' \
+		-e 's: -o : $(LDFLAGS)&:g' \
+		|| die "sed Makefile"
+}
+
+src_compile() {
+	emake CC=$(tc-getCC) || die
+}
+
+src_install() {
+	dobin ${PN} || die "dobin ${PN}"
+	insinto /etc
+	doins osprints.conf
+	dodoc README
+}