Version bump, bump EAPI and switch to append-cppflags

(Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key C74525F2)

2 files changed, 64 insertions, 1 deletions

diff --git a/net-ftp/filezilla/ChangeLog b/net-ftp/filezilla/ChangeLog
index 901474603b11..9b7dcd5bf7c8 100644
--- a/net-ftp/filezilla/ChangeLog
+++ b/net-ftp/filezilla/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-ftp/filezilla
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-ftp/filezilla/ChangeLog,v 1.92 2012/11/15 09:48:23 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/filezilla/ChangeLog,v 1.93 2012/11/19 09:48:18 voyageur Exp $
+
+*filezilla-3.6.0.1 (19 Nov 2012)
+
+  19 Nov 2012; Bernard Cafarelli <voyageur@gentoo.org>
+  +filezilla-3.6.0.1.ebuild:
+  Version bump, bump EAPI and switch to append-cppflags
 
   15 Nov 2012; Bernard Cafarelli <voyageur@gentoo.org> filezilla-3.6.0.ebuild:
   It builds with older gnutls, but only works with >=3.1. Thanks Andreas Prieß
diff --git a/net-ftp/filezilla/filezilla-3.6.0.1.ebuild b/net-ftp/filezilla/filezilla-3.6.0.1.ebuild
new file mode 100644
index 000000000000..b4703f96a636
--- /dev/null
+++ b/net-ftp/filezilla/filezilla-3.6.0.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/filezilla/filezilla-3.6.0.1.ebuild,v 1.1 2012/11/19 09:48:18 voyageur Exp $
+
+EAPI=5
+
+WX_GTK_VER="2.8"
+
+inherit autotools eutils flag-o-matic multilib wxwidgets
+
+MY_PV=${PV/_/-}
+MY_P="FileZilla_${MY_PV}"
+
+DESCRIPTION="FTP client with lots of useful features and an intuitive interface"
+HOMEPAGE="http://filezilla-project.org/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}_src.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~sparc ~x86"
+IUSE="dbus nls test"
+
+RDEPEND=">=app-admin/eselect-wxwidgets-0.7-r1
+	>=dev-db/sqlite-3.7
+	>=dev-libs/tinyxml-2.6.1-r1[stl]
+	net-dns/libidn
+	>=net-libs/gnutls-3.1
+	>=x11-libs/wxGTK-2.8.12:2.8[X]
+	x11-misc/xdg-utils
+	dbus? ( sys-apps/dbus )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	>=sys-devel/libtool-1.4
+	nls? ( >=sys-devel/gettext-0.11 )
+	test? ( dev-util/cppunit )"
+
+S="${WORKDIR}"/${PN}-${MY_PV}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-3.3.5.1-debug.patch
+	append-cppflags -DTIXML_USE_STL
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_with dbus) $(use_enable nls locales) \
+		--with-tinyxml=system \
+		--disable-autoupdatecheck
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	doicon src/interface/resources/48x48/${PN}.png
+
+	dodoc AUTHORS ChangeLog NEWS
+}