Version bump.

(Portage version: 2.2.0_alpha100/cvs/Linux x86_64)

2 files changed, 119 insertions, 1 deletions

diff --git a/net-libs/gnutls/ChangeLog b/net-libs/gnutls/ChangeLog
index ef8ed11fb6d4..58d50b66c6b1 100644
--- a/net-libs/gnutls/ChangeLog
+++ b/net-libs/gnutls/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/gnutls
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.355 2012/04/16 18:04:47 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.356 2012/04/22 21:45:17 radhermit Exp $
+
+*gnutls-3.0.19 (22 Apr 2012)
+
+  22 Apr 2012; Tim Harder <radhermit@gentoo.org> +gnutls-3.0.19.ebuild:
+  Version bump.
 
   16 Apr 2012; Brent Baude <ranger@gentoo.org> gnutls-2.12.18.ebuild:
   Marking gnutls-2.12.18 ppc for bug 409287
diff --git a/net-libs/gnutls/gnutls-3.0.19.ebuild b/net-libs/gnutls/gnutls-3.0.19.ebuild
new file mode 100644
index 000000000000..d82a962e75ff
--- /dev/null
+++ b/net-libs/gnutls/gnutls-3.0.19.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/gnutls-3.0.19.ebuild,v 1.1 2012/04/22 21:45:17 radhermit Exp $
+
+EAPI=4
+
+inherit autotools libtool eutils
+
+DESCRIPTION="A TLS 1.2 and SSL 3.0 implementation for the GNU project"
+HOMEPAGE="http://www.gnutls.org/"
+
+if [[ "${PV}" == *pre* ]]; then
+	SRC_URI="http://daily.josefsson.org/${P%.*}/${P%.*}-${PV#*pre}.tar.gz"
+else
+	MINOR_VERSION="${PV#*.}"
+	MINOR_VERSION="${MINOR_VERSION%%.*}"
+	if [[ $((MINOR_VERSION % 2)) == 0 ]]; then
+		#SRC_URI="ftp://ftp.gnu.org/pub/gnu/${PN}/${P}.tar.bz2"
+		SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
+	else
+		SRC_URI="ftp://alpha.gnu.org/gnu/${PN}/${P}.tar.xz"
+	fi
+	unset MINOR_VERSION
+fi
+
+# LGPL-3 for libgnutls library and GPL-3 for libgnutls-extra library.
+LICENSE="GPL-3 LGPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="+cxx doc examples guile nls pkcs11 static-libs test zlib"
+
+RDEPEND=">=dev-libs/libtasn1-0.3.4
+	>=dev-libs/nettle-2.4[gmp]
+	sys-devel/autogen
+	guile? ( >=dev-scheme/guile-1.8[networking] )
+	nls? ( virtual/libintl )
+	pkcs11? ( >=app-crypt/p11-kit-0.11 )
+	zlib? ( >=sys-libs/zlib-1.2.3.1 )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	sys-devel/libtool
+	doc? ( dev-util/gtk-doc )
+	nls? ( sys-devel/gettext )
+	test? ( app-misc/datefudge )"
+
+S="${WORKDIR}/${P%_pre*}"
+
+DOCS=( AUTHORS ChangeLog NEWS README THANKS doc/TODO )
+
+src_prepare() {
+	local dir file
+
+	# tests/suite directory is not distributed.
+	sed -i \
+		-e ':AC_CONFIG_FILES(\[tests/suite/Makefile\]):d' \
+		configure.ac || die
+
+	sed -i \
+		-e 's/imagesdir = $(infodir)/imagesdir = $(htmldir)/' \
+		doc/Makefile.am || die
+
+	for dir in m4 gl/m4; do
+		rm -f "${dir}/lt"* "${dir}/libtool.m4"
+	done
+	find . -name ltmain.sh -exec rm {} \;
+
+	# use system libopts
+	sed -i -e "/^enable_local_libopts/s/yes/no/" configure.ac || die
+
+	# force regeneration of autogen-ed files
+	for file in $(grep -l AutoGen-ed src/*.c) ; do
+		rm src/$(basename ${file} .c).{c,h} || die
+	done
+
+	# support user patches
+	epatch_user
+
+	eautoreconf
+
+	# Use sane .so versioning on FreeBSD.
+	elibtoolize
+}
+
+src_configure() {
+	econf \
+		--htmldir="${EPREFIX}/usr/share/doc/${PF}/html" \
+		--disable-valgrind-tests \
+		$(use_enable cxx) \
+		$(use_enable doc gtk-doc) \
+		$(use_enable doc gtk-doc-pdf) \
+		$(use_enable guile) \
+		$(use_enable nls) \
+		$(use_enable static-libs static) \
+		$(use_with pkcs11 p11-kit) \
+		$(use_with zlib) \
+		${myconf}
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -exec rm -f {} +
+
+	if use doc; then
+		dodoc doc/gnutls.{pdf,ps}
+		dohtml doc/gnutls.html
+	fi
+
+	if use examples; then
+		docinto examples
+		dodoc doc/examples/*.c
+	fi
+}