Add support for modular X.

(Portage version: 2.1_pre4-r1)

5 files changed, 101 insertions, 6 deletions

diff --git a/net-misc/lsh/ChangeLog b/net-misc/lsh/ChangeLog
index 5b81d53386fe..2a7ec91c9ab1 100644
--- a/net-misc/lsh/ChangeLog
+++ b/net-misc/lsh/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for net-misc/lsh
 # Copyright 1999-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/lsh/ChangeLog,v 1.8 2006/01/31 20:04:51 dertobi123 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/lsh/ChangeLog,v 1.9 2006/02/02 01:27:31 vapier Exp $
+
+  02 Feb 2006; Mike Frysinger <vapier@gentoo.org> lsh-2.0.1.ebuild,
+  lsh-2.0.1-r1.ebuild, +lsh-2.0.1-r2.ebuild:
+  Add support for modular X.
+
+*lsh-2.0.1-r2 (02 Feb 2006)
+
+  02 Feb 2006; Mike Frysinger <vapier@gentoo.org> +lsh-2.0.1-r2.ebuild:
+  Fix file collisions with openssh.
 
   31 Jan 2006; Tobias Scherbaum <dertobi123@gentoo.org> lsh-2.0.1-r1.ebuild:
   ppc stable, bug #119966
diff --git a/net-misc/lsh/files/digest-lsh-2.0.1-r2 b/net-misc/lsh/files/digest-lsh-2.0.1-r2
new file mode 100644
index 000000000000..689cda9ed926
--- /dev/null
+++ b/net-misc/lsh/files/digest-lsh-2.0.1-r2
@@ -0,0 +1 @@
+MD5 25ca0b4385779de3d58d2d5757f495c3 lsh-2.0.1.tar.gz 1866063
diff --git a/net-misc/lsh/lsh-2.0.1-r1.ebuild b/net-misc/lsh/lsh-2.0.1-r1.ebuild
index 1b0a7e4c4caa..103ba900f692 100644
--- a/net-misc/lsh/lsh-2.0.1-r1.ebuild
+++ b/net-misc/lsh/lsh-2.0.1-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2006 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/lsh/lsh-2.0.1-r1.ebuild,v 1.4 2006/01/31 20:04:51 dertobi123 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/lsh/lsh-2.0.1-r1.ebuild,v 1.5 2006/02/02 01:27:31 vapier Exp $
 
 inherit eutils
 
@@ -18,7 +18,7 @@ RDEPEND="dev-libs/gmp
 	dev-libs/liboop
 	dev-libs/nettle
 	zlib? ( sys-libs/zlib )
-	X? ( virtual/x11 )
+	X? ( || ( ( x11-libs/libXau ) virtual/x11 ) )
 	tcpd? ( sys-apps/tcp-wrappers )
 	pam? ( sys-libs/pam )"
 #	kerberos? ( virtual/krb5 )
diff --git a/net-misc/lsh/lsh-2.0.1-r2.ebuild b/net-misc/lsh/lsh-2.0.1-r2.ebuild
new file mode 100644
index 000000000000..062e220cb455
--- /dev/null
+++ b/net-misc/lsh/lsh-2.0.1-r2.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/lsh/lsh-2.0.1-r2.ebuild,v 1.1 2006/02/02 01:27:31 vapier Exp $
+
+inherit eutils
+
+DESCRIPTION="A GNU implementation of the Secure Shell protocols"
+HOMEPAGE="http://www.lysator.liu.se/~nisse/lsh/"
+SRC_URI="ftp://ftp.lysator.liu.se/pub/security/lsh/${P}.tar.gz
+	http://www.lysator.liu.se/~nisse/archive/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="pam tcpd ipv6 zlib X"
+
+RDEPEND="dev-libs/gmp
+	dev-libs/liboop
+	dev-libs/nettle
+	zlib? ( sys-libs/zlib )
+	X? ( || ( ( x11-libs/libXau ) virtual/x11 ) )
+	tcpd? ( sys-apps/tcp-wrappers )
+	pam? ( sys-libs/pam )"
+#	kerberos? ( virtual/krb5 )
+# need guile because the source changes
+DEPEND="${RDEPEND}
+	dev-util/guile
+	>=sys-apps/portage-2.0.51"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}"/${P}-fix-fd-leak.patch
+	# Rename 'sftp-server' to something that doesn't conflict with openssh
+	sed -i \
+		-e 's:sftp-server:lsh-sftp-server:' \
+		doc/{lshd.8,lsh.info} src/lshd.c src/sftp/sftp-server.[c8] \
+		|| die "rename sftp-server"
+	# remove bundled nettle crap #56156 ... this is pretty ugly sed foo,
+	# but the alternative is a bigger, uglier patch which would probably 
+	# need updating with every version :/
+	sed -i -e '/src\/nettle/d' configure || die "sed configure failed"
+	sed -i \
+		-e '/^SUBDIRS/s:nettle::' \
+		-e '/^LDADD/s:nettle/libnettle\.a:-lnettle:' \
+		-e 's:nettle/libnettle\.a::' \
+		src/Makefile.in || die "sed src failed"
+	sed -i \
+		-e 's:\.\./\.\./nettle/libnettle\.a::' \
+		src/spki/tools/Makefile.in || die "sed spki failed"
+	sed -i \
+		-e '/^LDADD/s:\.\./nettle/libnettle\.a:-lnettle:' \
+		-e 's:\.\./nettle/libnettle\.a::' \
+		src/testsuite/Makefile.in || die "sed test failed"
+	rm -r src/nettle
+}
+
+src_compile() {
+	# configure script checks /dev/ptmx in order to enable
+	# proper unix pty support ... so lets fake that it works :)
+	addpredict /dev/ptmx
+#		$(use_enable kerberos)
+	econf \
+		--disable-kerberos \
+		$(use_enable pam) \
+		$(use_enable ipv6) \
+		$(use_with zlib) \
+		$(use_with tcpd tcpwrappers) \
+		$(use_with X x) \
+		|| die
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake -j1 install DESTDIR="${D}" || die "install failed"
+	dodoc ANNOUNCE AUTHORS ChangeLog FAQ NEWS README
+
+	newinitd "${FILESDIR}"/lsh.rc lshd
+	newconfd "${FILESDIR}"/lsh.confd lshd
+
+	# cleanup conflicting crap
+	mv "${D}"/usr/sbin/{,lsh-}sftp-server || die
+	mv "${D}"/usr/share/man/man8/{,lsh-}sftp-server.8
+	rm -r "${D}"/usr/share/man/man5
+}
diff --git a/net-misc/lsh/lsh-2.0.1.ebuild b/net-misc/lsh/lsh-2.0.1.ebuild
index 503685146e75..3bae9d856e4f 100644
--- a/net-misc/lsh/lsh-2.0.1.ebuild
+++ b/net-misc/lsh/lsh-2.0.1.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2005 Gentoo Foundation
+# Copyright 1999-2006 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/lsh/lsh-2.0.1.ebuild,v 1.3 2005/05/01 17:24:08 hansmi Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/lsh/lsh-2.0.1.ebuild,v 1.4 2006/02/02 01:27:31 vapier Exp $
 
 inherit eutils
 
@@ -18,7 +18,7 @@ RDEPEND="dev-libs/gmp
 	dev-libs/liboop
 	dev-libs/nettle
 	zlib? ( sys-libs/zlib )
-	X? ( virtual/x11 )
+	X? ( || ( ( x11-libs/libXau ) virtual/x11 ) )
 	tcpd? ( sys-apps/tcp-wrappers )
 	pam? ( sys-libs/pam )"
 #	kerberos? ( virtual/krb5 )