Bump, includes fixes for bugs #516920 (ip6gre functionality) and #506966 (useful if you have a bad system clock).

(Portage version: 2.2.10/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 72 insertions, 1 deletions

diff --git a/net-misc/netifrc/ChangeLog b/net-misc/netifrc/ChangeLog
index 28d4c8190a88..0fa6cee86fe8 100644
--- a/net-misc/netifrc/ChangeLog
+++ b/net-misc/netifrc/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/netifrc
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/netifrc/ChangeLog,v 1.32 2014/07/14 18:36:07 zlogene Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/netifrc/ChangeLog,v 1.33 2014/07/16 19:21:58 robbat2 Exp $
+
+*netifrc-0.2.4 (16 Jul 2014)
+
+  16 Jul 2014; Robin H. Johnson <robbat2@gentoo.org> +netifrc-0.2.4.ebuild:
+  Bump, includes fixes for bugs #516920 (ip6gre functionality) and #506966
+  (useful if you have a bad system clock).
 
   14 Jul 2014; Mikle Kolyada <zlogene@gentoo.org> netifrc-0.2.2.ebuild:
   ia64 stable wrt bug #507070
diff --git a/net-misc/netifrc/netifrc-0.2.4.ebuild b/net-misc/netifrc/netifrc-0.2.4.ebuild
new file mode 100644
index 000000000000..028bf283658e
--- /dev/null
+++ b/net-misc/netifrc/netifrc-0.2.4.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/netifrc/netifrc-0.2.4.ebuild,v 1.1 2014/07/16 19:21:58 robbat2 Exp $
+
+EAPI=5
+
+inherit eutils udev
+
+DESCRIPTION="Gentoo Network Interface Management Scripts"
+HOMEPAGE="http://www.gentoo.org/proj/en/base/openrc/"
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="git://git.overlays.gentoo.org/proj/${PN}.git"
+	inherit git-2
+else
+	SRC_URI="http://dev.gentoo.org/~robbat2/distfiles/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+fi
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE=""
+
+COMMON_DEPEND="!<sys-fs/udev-init-scripts-26-r1"
+DEPEND="${COMMON_DEPEND}
+	kernel_linux? ( virtual/pkgconfig )"
+RDEPEND="${COMMON_DEPEND}
+	>=sys-apps/openrc-0.12
+	!<sys-apps/openrc-0.12"
+
+src_prepare() {
+	if [[ ${PV} == "9999" ]] ; then
+		local ver="git-${EGIT_VERSION:0:6}"
+		sed -i "/^GITVER[[:space:]]*=/s:=.*:=${ver}:" mk/git.mk || die
+		einfo "Producing ChangeLog from Git history"
+		GIT_DIR="${S}/.git" git log >"${S}"/ChangeLog
+	fi
+
+	# Allow user patches to be applied without modifying the ebuild
+	epatch_user
+}
+
+src_compile() {
+	MAKE_ARGS="${MAKE_ARGS}
+		LIBEXECDIR=${EPREFIX}/lib/${PN} PF=${PF}
+		UDEVDIR=$(get_udevdir)"
+
+	use prefix && MAKE_ARGS="${MAKE_ARGS} MKPREFIX=yes PREFIX=${EPREFIX}"
+
+	emake ${MAKE_ARGS} all
+}
+
+src_install() {
+	emake ${MAKE_ARGS} DESTDIR="${D}" install
+	dodoc README CREDITS FEATURE-REMOVAL-SCHEDULE STYLE TODO ChangeLog
+}
+
+pkg_postinst() {
+	if [[ ! -e "${EROOT}"/etc/conf.d/net && -z $REPLACING_VERSIONS ]]; then
+		elog "The network configuration scripts will use dhcp by"
+		elog "default to set up your interfaces."
+		elog "If you need to set up something more complete, see"
+		elog "${EROOT}/usr/share/doc/${P}/README"
+	fi
+}