Version bump, includes new system to define NX keystrokes

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key C74525F2)

2 files changed, 102 insertions, 2 deletions

diff --git a/net-misc/nx/ChangeLog b/net-misc/nx/ChangeLog
index 5b4ee1ae8036..7a58a6939c38 100644
--- a/net-misc/nx/ChangeLog
+++ b/net-misc/nx/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/nx
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/nx/ChangeLog,v 1.74 2012/12/16 16:29:05 ago Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/nx/ChangeLog,v 1.75 2013/01/08 10:47:02 voyageur Exp $
+
+*nx-3.5.0.17 (08 Jan 2013)
+
+  08 Jan 2013; Bernard Cafarelli <voyageur@gentoo.org> +nx-3.5.0.17.ebuild:
+  Version bump, includes new system to define NX keystrokes
 
   16 Dec 2012; Agostino Sarubbo <ago@gentoo.org> nx-3.5.0.15.ebuild:
   Stable for x86, wrt bug #445766
diff --git a/net-misc/nx/nx-3.5.0.17.ebuild b/net-misc/nx/nx-3.5.0.17.ebuild
new file mode 100644
index 000000000000..714e864512a5
--- /dev/null
+++ b/net-misc/nx/nx-3.5.0.17.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/nx/nx-3.5.0.17.ebuild,v 1.1 2013/01/08 10:47:02 voyageur Exp $
+
+EAPI=4
+inherit autotools eutils multilib
+
+DESCRIPTION="NX compression technology core libraries"
+HOMEPAGE="http://www.nomachine.com/developers.php
+	http://www.x2go.org/doku.php/wiki:libs:nx-libs"
+
+SRC_URI="http://code.x2go.org/releases/source/nx-libs/nx-libs-${PV}-full.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="elibc_glibc"
+
+RDEPEND="elibc_glibc? ( || ( net-libs/libtirpc <sys-libs/glibc-2.14 ) )
+	>=media-libs/libpng-1.2.8
+	>=sys-libs/zlib-1.2.3
+	virtual/jpeg"
+
+DEPEND="${RDEPEND}
+		x11-misc/gccmakedep
+		x11-misc/imake
+		x11-proto/inputproto"
+
+S=${WORKDIR}/nx-libs-${PV}
+
+src_prepare() {
+	# For nxcl/qtnx
+	cd "${S}"/nxproxy
+	epatch "${FILESDIR}"/${PN}-3.2.0-nxproxy_read_from_stdin.patch
+
+	cd "${S}"
+	# Fix sandbox violation
+	epatch "${FILESDIR}"/1.5.0/nx-x11-1.5.0-tmp-exec.patch
+	# -fPIC
+	epatch "${FILESDIR}"/1.5.0/nxcomp-1.5.0-pic.patch
+	# Drop force -O3 and run autoreconf in all neeed folders
+	for i in nxcomp nxcompext nxcompshad nxproxy; do
+		cd "${S}"/${i}
+		sed -e "s/-O3//" -i configure.in ||  die "$i configure sed failed"
+		eautoreconf ${i}
+		cd "${S}"
+	done
+
+	# From xorg-x11-6.9.0-r3.ebuild
+	cd "${S}/nx-X11"
+	HOSTCONF="config/cf/host.def"
+	echo "#define CcCmd $(tc-getCC)" >> ${HOSTCONF}
+	echo "#define OptimizedCDebugFlags ${CFLAGS} GccAliasingArgs" >> ${HOSTCONF}
+	echo "#define OptimizedCplusplusDebugFlags ${CXXFLAGS} GccAliasingArgs" >> ${HOSTCONF}
+	# Respect LDFLAGS
+	echo "#define ExtraLoadFlags ${LDFLAGS}" >> ${HOSTCONF}
+	echo "#define SharedLibraryLoadFlags -shared ${LDFLAGS}" >> ${HOSTCONF}
+}
+
+src_configure() {
+	cd "${S}"/nxproxy
+	econf
+}
+
+src_compile() {
+	cd "${S}/nx-X11"
+	FAST=1 emake World WORLDOPTS="" MAKE="make"
+
+	cd "${S}"/nxproxy
+	emake
+}
+
+src_install() {
+	NX_ROOT=/usr/$(get_libdir)/NX
+
+	for x in nxagent nxauth nxproxy; do
+		make_wrapper $x ./$x ${NX_ROOT}/bin ${NX_ROOT}/$(get_libdir) ||
+			die " $x wrapper creation failed"
+	done
+
+	into ${NX_ROOT}
+	dobin "${S}"/nx-X11/programs/Xserver/nxagent
+	dobin "${S}"/nx-X11/programs/nxauth/nxauth
+	dobin "${S}"/nxproxy/nxproxy
+
+	for lib in X11 Xau Xcomposite Xdamage Xdmcp Xext Xfixes Xinerama Xpm Xrandr Xrender Xtst;
+	do
+		dolib.so "${S}"/nx-X11/lib/${lib}/libNX_${lib}.so*
+	done
+	dolib.so "${S}"/nx-X11/lib/freetype2/libNX_freetype.so*
+
+	dolib.so "${S}"/nxcomp/libXcomp.so*
+	dolib.so "${S}"/nxcompext/libXcompext.so*
+	dolib.so "${S}"/nxcompshad/libXcompshad.so*
+}