Version bump, fix compilation with glibmm 2.31 or greater. Drop old

(Portage version: 2.2.0_alpha86/cvs/Linux x86_64)

3 files changed, 66 insertions, 54 deletions

diff --git a/net-misc/sobby/ChangeLog b/net-misc/sobby/ChangeLog
index 9adce51f3a9f..4a1d299fee26 100644
--- a/net-misc/sobby/ChangeLog
+++ b/net-misc/sobby/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/sobby
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/sobby/ChangeLog,v 1.28 2012/02/03 22:35:38 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/sobby/ChangeLog,v 1.29 2012/02/19 16:32:36 xarthisius Exp $
+
+*sobby-0.4.8 (19 Feb 2012)
+
+  19 Feb 2012; Kacper Kowalik <xarthisius@gentoo.org> +sobby-0.4.8.ebuild,
+  -sobby-0.4.5.ebuild:
+  Version bump, fix compilation with glibmm 2.31 or greater. Drop old
 
   03 Feb 2012; Brent Baude <ranger@gentoo.org> sobby-0.4.7.ebuild:
   Marking sobby-0.4.7 ppc for bug 394059
diff --git a/net-misc/sobby/sobby-0.4.5.ebuild b/net-misc/sobby/sobby-0.4.5.ebuild
deleted file mode 100644
index c3fd3ed42860..000000000000
--- a/net-misc/sobby/sobby-0.4.5.ebuild
+++ /dev/null
@@ -1,53 +0,0 @@
-# Copyright 1999-2009 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/sobby/sobby-0.4.5.ebuild,v 1.3 2009/11/23 14:42:36 maekke Exp $
-
-inherit eutils
-
-DESCRIPTION="Standalone Obby server"
-HOMEPAGE="http://gobby.0x539.de/"
-SRC_URI="http://releases.0x539.de/${PN}/${P}.tar.gz"
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 ppc x86"
-IUSE="avahi"
-
-RDEPEND=">=dev-cpp/glibmm-2.6
-	>=dev-libs/libsigc++-2.0
-	>=dev-libs/gmp-4.1.4
-	>=dev-cpp/libxmlpp-2.6
-	>=net-libs/obby-0.4.6"
-DEPEND="${RDEPEND}
-	dev-util/pkgconfig"
-
-pkg_setup() {
-	if use avahi && ! built_with_use net-libs/obby avahi ; then
-		eerror "Please reinstall net-libs/obby with the avahi USE-flag enabled"
-		eerror "for zeroconf/DNS-SD support or disable it for this package."
-		die "Missing 'avahi' USE-flag for net-libs/obby"
-	fi
-}
-
-src_compile() {
-	econf \
-		$(use_enable avahi zeroconf) \
-		|| die "econf failed"
-	emake || die "emake failed"
-}
-
-src_install() {
-	emake DESTDIR="${D}" install || die "emake install failed"
-
-	dodoc AUTHORS ChangeLog NEWS README
-
-	newconfd "${FILESDIR}/sobby-conf-0.4.3" sobby
-	newinitd "${FILESDIR}/sobby-init-0.4.3" sobby
-}
-
-pkg_postinst() {
-	elog "To start sobby, you can use the init script:"
-	elog "    /etc/init.d/sobby start"
-	elog ""
-	elog "Please check the configuration in /etc/conf.d/sobby"
-	elog "before you start sobby"
-}
diff --git a/net-misc/sobby/sobby-0.4.8.ebuild b/net-misc/sobby/sobby-0.4.8.ebuild
new file mode 100644
index 000000000000..238f6038657f
--- /dev/null
+++ b/net-misc/sobby/sobby-0.4.8.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/sobby/sobby-0.4.8.ebuild,v 1.1 2012/02/19 16:32:36 xarthisius Exp $
+
+EAPI=4
+
+inherit eutils
+
+DESCRIPTION="Standalone Obby server"
+HOMEPAGE="http://gobby.0x539.de/"
+SRC_URI="http://releases.0x539.de/${PN}/${P}.tar.gz"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="avahi"
+
+RDEPEND=">=dev-cpp/glibmm-2.6
+	>=dev-libs/libsigc++-2.0
+	>=dev-libs/gmp-4.1.4
+	>=dev-cpp/libxmlpp-2.6
+	>=net-libs/net6-1.3.12
+	>=net-libs/obby-0.4.6[avahi=]"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+pkg_setup() {
+	enewgroup sobby
+	enewuser sobby -1 -1 /var/lib/sobby sobby
+}
+
+src_configure() {
+	econf $(use_enable avahi zeroconf)
+}
+
+src_install() {
+	default
+
+	newconfd "${FILESDIR}/${PN}-conf-0.4.7" sobby
+	newinitd "${FILESDIR}/${PN}-init-0.4.7" sobby
+
+	insinto /etc/sobby
+	doins "${FILESDIR}/sobby.xml"
+
+	keepdir /var/lib/sobby
+
+	fperms -R 0700 /var/lib/sobby
+	fperms -R 0700 /etc/sobby
+
+	fowners sobby:sobby /var/lib/sobby
+	fowners -R sobby:sobby /etc/sobby
+}
+
+pkg_postinst() {
+	elog "To start sobby, you can use the init script:"
+	elog "    /etc/init.d/sobby start"
+	elog ""
+	elog "Please check the configuration in /etc/sobby/sobby.xml"
+	elog "before you start sobby"
+}