New snapshot which incorporates upstream fixes for lost connections du to rekeying errors (bug 350219 by Lori <ljakab AT ac DOT upc DOT edu>), an updated external vpnc-script which has support for Solaris and IPv6 (bug 331445 by ByrneG <gentoo-bugzilla-byrne AT gzone DOT org>), patches taken from upstream mailing list that fix some dead lock problems in the socket handling routines (also bug 350219). Also reenable OpenSSL for hybrid-auth, but check for binary distribution (bug 336012). Lots of thanks to Martin Mokrejs <mmokejs AT fold DOT natur DOT cuni DOT cz> who worked on all the bugs and provided a lot of feedback.

# Please enter the ChangeLog message for your changes. Lines starting
# with '#' will be ignored, and an empty message aborts the ChangeLog.
#
# Changes:
# modified:	Manifest
# new file:	vpnc-0.5.3_p451.ebuild

(Portage version: 2.1.9.25/cvs/Linux i686)

1 files changed, 61 insertions, 0 deletions

diff --git a/net-misc/vpnc/vpnc-0.5.3_p451.ebuild b/net-misc/vpnc/vpnc-0.5.3_p451.ebuild
new file mode 100644
index 000000000000..5b9eb8f42ac0
--- /dev/null
+++ b/net-misc/vpnc/vpnc-0.5.3_p451.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/vpnc/vpnc-0.5.3_p451.ebuild,v 1.1 2011/01/03 15:24:06 fauli Exp $
+
+EAPI=3
+
+DESCRIPTION="Free client for Cisco VPN routing software"
+HOMEPAGE="http://www.unix-ag.uni-kl.de/~massar/vpnc/"
+# Modified vpnc-script taken from
+# http://git.infradead.org/users/dwmw2/vpnc-scripts.git, supports Solaris and IP v6, as reported in bug
+# Additionally added patches to fix some dead lock problems taken from
+# http://lists.unix-ag.uni-kl.de/pipermail/vpnc-devel/2010-March/003445.html
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+
+LICENSE="GPL-2 BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
+IUSE="resolvconf gnutls bindist"
+
+DEPEND=">=dev-libs/libgcrypt-1.1.91
+	>=sys-apps/iproute2-2.6.19.20061214
+	gnutls? ( net-libs/gnutls )
+	bindist? ( net-libs/gnutls )
+	!gnutls? (
+		!bindist? ( dev-libs/openssl )
+	)"
+
+RDEPEND="${DEPEND}
+	resolvconf? ( net-dns/openresolv )"
+
+src_prepare() {
+	if ! use gnutls && ! use bindist; then
+		sed -i -e 's/#OPENSSL_GPL_VIOLATION=yes/OPENSSL_GPL_VIOLATION=yes/' "${S}"/Makefile \
+			|| die
+		ewarn "Building SSL support with OpenSSL instead of GnuTLS.  This means that"
+		ewarn "you are not allowed to re-distibute the binaries due to conflicts between BSD license and GPL,"
+		ewarn "see the vpnc Makefile and http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=440318"
+	else
+		elog "Will build with GnuTLS (default) instead of OpenSSL so you may even redistribute binaries."
+		elog "See the Makefile itself and http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=440318"
+	fi
+}
+
+src_install() {
+	emake PREFIX="/usr" DESTDIR="${D}" install || die
+	dodoc README TODO VERSION || die
+	keepdir /etc/vpnc/scripts.d
+	newinitd "${FILESDIR}/vpnc-3.init" vpnc || die
+	newconfd "${FILESDIR}/vpnc.confd" vpnc || die
+	sed -e "s:/usr/local:/usr:" -i "${D}"/etc/vpnc/vpnc-script || die
+	# COPYING file resides here, should not be installed
+	rm -rf "${D}"/usr/share/doc/vpnc/
+}
+
+pkg_postinst() {
+	elog "You can generate a configuration file from the original Cisco profiles of your"
+	elog "connection by using /usr/bin/pcf2vpnc to convert the .pcf file"
+	elog "A guide is available in http://www.gentoo.org/doc/en/vpnc-howto.xml"
+	echo
+	elog "Don't forget to turn on TUN support in the kernel."
+}