Version bump, drop old

(Portage version: 2.1.12.2/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

2 files changed, 25 insertions, 25 deletions

diff --git a/net-misc/networkmanager-openvpn/ChangeLog b/net-misc/networkmanager-openvpn/ChangeLog
index 2e0515451d46..0046e51fbf0d 100644
--- a/net-misc/networkmanager-openvpn/ChangeLog
+++ b/net-misc/networkmanager-openvpn/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/networkmanager-openvpn
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager-openvpn/ChangeLog,v 1.39 2013/04/07 15:12:05 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager-openvpn/ChangeLog,v 1.40 2013/06/10 09:36:23 pacho Exp $
+
+*networkmanager-openvpn-0.9.8.2 (10 Jun 2013)
+
+  10 Jun 2013; Pacho Ramos <pacho@gentoo.org>
+  +networkmanager-openvpn-0.9.8.2.ebuild,
+  -networkmanager-openvpn-0.9.4.0.ebuild:
+  Version bump, drop old
 
 *networkmanager-openvpn-0.9.8.0 (07 Apr 2013)
 
diff --git a/net-misc/networkmanager-openvpn/networkmanager-openvpn-0.9.4.0.ebuild b/net-misc/networkmanager-openvpn/networkmanager-openvpn-0.9.8.2.ebuild
index 456b0e689ca0..29d8fc249fa6 100644
--- a/net-misc/networkmanager-openvpn/networkmanager-openvpn-0.9.4.0.ebuild
+++ b/net-misc/networkmanager-openvpn/networkmanager-openvpn-0.9.8.2.ebuild
@@ -1,23 +1,23 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager-openvpn/networkmanager-openvpn-0.9.4.0.ebuild,v 1.5 2012/08/17 09:44:24 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager-openvpn/networkmanager-openvpn-0.9.8.2.ebuild,v 1.1 2013/06/10 09:36:23 pacho Exp $
 
-EAPI="4"
+EAPI=5
 GNOME_ORG_MODULE="NetworkManager-${PN##*-}"
 
-inherit gnome.org
+inherit eutils gnome2-utils gnome.org
 
 DESCRIPTION="NetworkManager OpenVPN plugin"
 HOMEPAGE="http://www.gnome.org/projects/NetworkManager/"
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="amd64 x86"
+KEYWORDS="~amd64 ~x86"
 IUSE="gtk test"
 
 RDEPEND="
 	>=dev-libs/dbus-glib-0.74
-	>=net-misc/networkmanager-${PV}
+	>=net-misc/networkmanager-0.9.8
 	>=net-misc/openvpn-2.1_rc9
 	gtk? (
 		>=x11-libs/gtk+-2.91.4:3
@@ -27,7 +27,8 @@ RDEPEND="
 DEPEND="${RDEPEND}
 	sys-devel/gettext
 	>=dev-util/intltool-0.35
-	virtual/pkgconfig"
+	virtual/pkgconfig
+"
 
 src_prepare() {
 	# Test will fail if the machine doesn't have a particular locale installed
@@ -35,28 +36,20 @@ src_prepare() {
 	sed '/test_non_utf8_import (plugin, test_dir)/ d' \
 		-i properties/tests/test-import-export.c || die "sed failed"
 
-	# Drop DEPRECATED flags, bug #385597
-	sed -i -e 's:-D[A-Z_]*DISABLE_DEPRECATED:$(NULL):g' \
-		auth-dialog/Makefile.am auth-dialog/Makefile.in \
-		common/Makefile.am common/Makefile.in \
-		properties/Makefile.am properties/Makefile.in \
-		src/Makefile.am src/Makefile.in \
-		configure.ac configure || die
+	gnome2_disable_deprecation_warning
 }
 
 src_configure() {
-	ECONF="--disable-more-warnings
-		--disable-static
-		--with-dist-version=Gentoo
-		--with-gtkver=3
-		$(use_with gtk gnome)
-		$(use_with test tests)"
-
-	econf ${ECONF}
+	econf \
+		--disable-more-warnings \
+		--disable-static \
+		--with-dist-version=Gentoo \
+		--with-gtkver=3 \
+		$(use_with gtk gnome) \
+		$(use_with test tests)
 }
 
 src_install() {
 	default
-	# Remove useless .la files
-	find "${D}" -name '*.la' -exec rm -f {} +
+	prune_libtool_files
 }