Convert to distutils-r1.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 63 insertions, 2 deletions

diff --git a/net-p2p/bittornado/ChangeLog b/net-p2p/bittornado/ChangeLog
index c2e1fc4dc3d1..a76f54787c9b 100644
--- a/net-p2p/bittornado/ChangeLog
+++ b/net-p2p/bittornado/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-p2p/bittornado
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/bittornado/ChangeLog,v 1.74 2012/08/12 22:07:25 ottxor Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/bittornado/ChangeLog,v 1.75 2014/12/25 10:58:59 mgorny Exp $
+
+*bittornado-0.3.18-r3 (25 Dec 2014)
+
+  25 Dec 2014; Michał Górny <mgorny@gentoo.org> +bittornado-0.3.18-r3.ebuild:
+  Convert to distutils-r1.
 
   12 Aug 2012; Christoph Junghans <ottxor@gentoo.org>
   bittornado-0.3.18-r2.ebuild:
diff --git a/net-p2p/bittornado/bittornado-0.3.18-r3.ebuild b/net-p2p/bittornado/bittornado-0.3.18-r3.ebuild
new file mode 100644
index 000000000000..de526463dfcc
--- /dev/null
+++ b/net-p2p/bittornado/bittornado-0.3.18-r3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/bittornado/bittornado-0.3.18-r3.ebuild,v 1.1 2014/12/25 10:58:59 mgorny Exp $
+
+# note: wxGTK interface has been removed wrt #391685. this ebuild is only for
+# cmdline tools as is.
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 eutils
+
+MY_PN=BitTornado
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="TheShad0w's experimental BitTorrent client"
+HOMEPAGE="http://www.bittornado.com/"
+SRC_URI="http://download2.bittornado.com/download/${MY_P}.tar.gz"
+LICENSE="MIT"
+SLOT="0"
+
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE=""
+
+RDEPEND="dev-python/pycrypto[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	>=sys-apps/sed-4.0.5"
+
+S=${WORKDIR}/${MY_PN}-CVS
+PIXMAPLOC=/usr/share/pixmaps/bittornado
+
+python_prepare_all() {
+	# fixes wrong icons path
+	sed -i "s:os.path.abspath(os.path.dirname(os.path.realpath(sys.argv\[0\]))):\"${PIXMAPLOC}/\":" btdownloadgui.py
+	# Needs wxpython-2.6 only, bug #201247
+	epatch "${FILESDIR}"/${P}-wxversion.patch
+
+	distutils-r1_python_prepare_all
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# get rid of any reference to the not-installed gui version
+	rm "${ED%/}"/usr/bin/*gui.py || die
+	rm "${ED%/}$(python_get_scriptdir)"/*gui.py || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newconfd "${FILESDIR}"/bttrack.conf bttrack
+	newinitd "${FILESDIR}"/bttrack.rc bttrack
+}