Version bump (bug #289902). Also solves bug #274085 (stripping bogus line), bug #274894 (drop dep on notification-daemon completely, automatically pulled in via notify-python), bug #283721 (solved by upstream), bug #315893 (use get_python_sitedir), bug #316507 (added --disable-static and rm *.la file), bug #285907 (solved by upstream).

(Portage version: 2.2_rc67/cvs/Linux x86_64)

2 files changed, 89 insertions, 1 deletions

diff --git a/net-wireless/blueman/ChangeLog b/net-wireless/blueman/ChangeLog
index 585d6f3d4e78..3ecd8bc7f65c 100644
--- a/net-wireless/blueman/ChangeLog
+++ b/net-wireless/blueman/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for net-wireless/blueman
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/ChangeLog,v 1.5 2010/04/25 15:43:08 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/ChangeLog,v 1.6 2010/05/11 07:54:00 dev-zero Exp $
+
+*blueman-1.21 (11 May 2010)
+
+  11 May 2010; Tiziano Müller <dev-zero@gentoo.org> +blueman-1.21.ebuild:
+  Version bump (bug #289902). Also solves bug #274085 (stripping bogus
+  line), bug #274894 (drop dep on notification-daemon completely,
+  automatically pulled in via notify-python), bug #283721 (solved by
+  upstream), bug #315893 (use get_python_sitedir), bug #316507 (added
+  --disable-static and rm *.la file), bug #285907 (solved by upstream).
 
   25 Apr 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
   blueman-1.02.ebuild, blueman-1.10.ebuild:
diff --git a/net-wireless/blueman/blueman-1.21.ebuild b/net-wireless/blueman/blueman-1.21.ebuild
new file mode 100644
index 000000000000..227f97dfc565
--- /dev/null
+++ b/net-wireless/blueman/blueman-1.21.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/blueman-1.21.ebuild,v 1.1 2010/05/11 07:54:00 dev-zero Exp $
+
+EAPI="3"
+
+PYTHON_DEPEND="2"
+
+inherit python
+
+DESCRIPTION="GTK+ Bluetooth Manager, designed to be simple and intuitive for everyday bluetooth tasks."
+HOMEPAGE="http://blueman-project.org/"
+SRC_URI="http://download.tuxfamily.org/${PN}/${P}.tar.gz"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnome hal network nls pulseaudio"
+
+CDEPEND="dev-libs/glib:2
+	>=x11-libs/gtk+-2.12:2
+	x11-libs/startup-notification
+	dev-python/pygobject
+	>=net-wireless/bluez-4.21"
+DEPEND="${CDEPEND}
+	nls? ( dev-util/intltool sys-devel/gettext )
+	dev-util/pkgconfig
+	>=dev-python/pyrex-0.9.8"
+RDEPEND="${CDEPEND}
+	>=app-mobilephone/obex-data-server-0.4.4
+	sys-apps/dbus
+	dev-python/pygtk
+	dev-python/notify-python
+	dev-python/dbus-python
+	gnome? ( dev-python/gconf-python )
+	network? ( || ( net-dns/dnsmasq
+		=net-misc/dhcp-3*
+		>=net-misc/networkmanager-0.8 ) )
+	pulseaudio? ( media-sound/pulseaudio )"
+
+# TODO:
+# - add policykit-support as soon as policykit-1 is available in the tree
+
+src_prepare() {
+	# disable pyc compiling
+	ln -sf $(type -P true) py-compile
+
+	sed -i \
+		-e '/^Encoding/d' \
+		data/blueman-manager.desktop.in || die "sed failed"
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--disable-polkit \
+		$(use_enable hal) \
+		$(use_enable nls)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS ChangeLog NEWS README
+
+	rm "${D}"/$(python_get_sitedir)/*.la
+	rm -rf "${D}/usr/share/polkit-1"
+
+	use gnome || rm "${D}/$(python_get_sitedir)/${PN}/plugins/config/Gconf.py"
+	use pulseaudio || rm "${D}"/$(python_get_sitedir)/${PN}/{main/Pulse*.py,plugins/applet/Pulse*.py}
+
+	python_need_rebuild
+}
+
+pkg_postinst() {
+	python_mod_optimize "${PN}"
+}
+
+pkg_postrm() {
+	python_mod_cleanup "${PN}"
+}