sci-chemistry/relax: Version Bump

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

2 files changed, 75 insertions, 1 deletions

diff --git a/sci-chemistry/relax/ChangeLog b/sci-chemistry/relax/ChangeLog
index 642a9b060f91..d1f8f0a9e6d9 100644
--- a/sci-chemistry/relax/ChangeLog
+++ b/sci-chemistry/relax/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sci-chemistry/relax
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/relax/ChangeLog,v 1.29 2014/11/17 08:54:44 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/relax/ChangeLog,v 1.30 2014/11/25 08:21:39 jlec Exp $
+
+*relax-3.3.3 (25 Nov 2014)
+
+  25 Nov 2014; Justin Lecher <jlec@gentoo.org> +relax-3.3.3.ebuild:
+  Version Bump
 
 *relax-3.3.2 (17 Nov 2014)
 
diff --git a/sci-chemistry/relax/relax-3.3.3.ebuild b/sci-chemistry/relax/relax-3.3.3.ebuild
new file mode 100644
index 000000000000..c9f36d6301ec
--- /dev/null
+++ b/sci-chemistry/relax/relax-3.3.3.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/relax/relax-3.3.3.ebuild,v 1.1 2014/11/25 08:21:39 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+WX_GTK_VER="2.9"
+
+inherit eutils multiprocessing python-single-r1 scons-utils toolchain-funcs wxwidgets virtualx
+
+DESCRIPTION="Molecular dynamics by NMR data analysis"
+HOMEPAGE="http://www.nmr-relax.com/"
+SRC_URI="http://download.gna.org/relax/${P}.src.tar.bz2"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-python/Numdifftools[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/wxpython:${WX_GTK_VER}[${PYTHON_USEDEP}]
+	sci-chemistry/molmol
+	sci-chemistry/pymol[${PYTHON_USEDEP}]
+	sci-chemistry/vmd
+	>=sci-libs/bmrblib-1.0.3[${PYTHON_USEDEP}]
+	>=sci-libs/minfx-1.0.11[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	sci-visualization/grace
+	sci-visualization/opendx
+	x11-libs/wxGTK:${WX_GTK_VER}[X]"
+DEPEND="${RDEPEND}
+	media-gfx/pngcrush"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	rm -rf minfx bmrblib extern/numdifftools || die
+	tc-export CC
+}
+
+src_compile() {
+	escons
+}
+
+src_test() {
+	VIRTUALX_COMMAND="${EPYTHON} ./${PN}.py -x --traceback"
+	virtualmake
+}
+
+src_install() {
+	dodoc README docs/{CHANGES,COMMITTERS,JOBS,relax.pdf}
+
+	python_moduleinto ${PN}
+	python_domodule *
+
+	rm ${PN} README || die
+
+	make_wrapper ${PN}-nmr "${EPYTHON} $(python_get_sitedir)/${PN}/${PN}.py $@"
+}