Drop --without-included-regex as it breaks systems more than it saves size.

(Portage version: 2.2.0_alpha43/cvs/Linux x86_64)

1 files changed, 48 insertions, 0 deletions

diff --git a/sys-apps/findutils/findutils-4.5.10-r1.ebuild b/sys-apps/findutils/findutils-4.5.10-r1.ebuild
new file mode 100644
index 000000000000..b8706f9d2200
--- /dev/null
+++ b/sys-apps/findutils/findutils-4.5.10-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/findutils/findutils-4.5.10-r1.ebuild,v 1.1 2011/07/05 21:08:17 vapier Exp $
+
+inherit eutils flag-o-matic toolchain-funcs multilib
+
+DESCRIPTION="GNU utilities for finding files"
+HOMEPAGE="http://www.gnu.org/software/findutils/"
+SRC_URI="ftp://alpha.gnu.org/gnu/${PN}/${P}.tar.gz"
+#	mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="nls selinux static"
+
+RDEPEND="selinux? ( sys-libs/libselinux )
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	# Don't build or install locate because it conflicts with slocate,
+	# which is a secure version of locate.  See bug 18729
+	sed -i '/^SUBDIRS/s/locate//' Makefile.in
+}
+
+src_compile() {
+	use static && append-ldflags -static
+
+	local myconf
+	use userland_GNU || myconf=" --program-prefix=g"
+
+	econf \
+		$(use_enable nls) \
+		--libexecdir=/usr/$(get_libdir)/find \
+		${myconf} \
+		|| die "configure failed"
+	emake AR="$(tc-getAR)" || die "make failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc NEWS README TODO ChangeLog
+}