Version bump.

(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 64 insertions, 1 deletions

diff --git a/sys-apps/moreutils/ChangeLog b/sys-apps/moreutils/ChangeLog
index 20115964fa6f..e3e793f186dc 100644
--- a/sys-apps/moreutils/ChangeLog
+++ b/sys-apps/moreutils/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/moreutils
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/moreutils/ChangeLog,v 1.65 2014/06/09 09:01:51 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/moreutils/ChangeLog,v 1.66 2014/10/08 01:01:02 radhermit Exp $
+
+*moreutils-0.52 (08 Oct 2014)
+
+  08 Oct 2014; Tim Harder <radhermit@gentoo.org> +moreutils-0.52.ebuild:
+  Version bump.
 
   09 Jun 2014; Tobias Klausmann <klausman@gentoo.org> moreutils-0.51.ebuild:
   Keyword moreutils-0.51 on alpha
diff --git a/sys-apps/moreutils/moreutils-0.52.ebuild b/sys-apps/moreutils/moreutils-0.52.ebuild
new file mode 100644
index 000000000000..77cda8ce1fa0
--- /dev/null
+++ b/sys-apps/moreutils/moreutils-0.52.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/moreutils/moreutils-0.52.ebuild,v 1.1 2014/10/08 01:01:02 radhermit Exp $
+
+EAPI=5
+inherit eutils toolchain-funcs
+
+DESCRIPTION="a growing collection of the unix tools that nobody thought to write thirty years ago"
+HOMEPAGE="http://joeyh.name/code/moreutils/"
+SRC_URI="mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~x86 ~x86-linux"
+IUSE="+doc +perl"
+
+RDEPEND="
+	perl? (
+		dev-lang/perl
+		dev-perl/IPC-Run
+		dev-perl/Time-Duration
+		dev-perl/TimeDate
+	)"
+DEPEND="
+	doc? (
+		dev-lang/perl
+		>=app-text/docbook2X-0.8.8-r2
+		app-text/docbook-xml-dtd:4.4
+	)"
+
+S=${WORKDIR}/${PN}
+
+src_prepare() {
+	# don't build manpages
+	if ! use doc ; then
+		sed -i -e '/^all:/s/$(MANS)//' -e '/man1/d' Makefile || die
+	fi
+
+	# don't install perl scripts
+	if ! use perl ; then
+		sed -i -e '/PERLSCRIPTS/d' Makefile || die
+	fi
+}
+
+src_compile() {
+	tc-export CC
+	emake CFLAGS="${CFLAGS}" DOCBOOK2XMAN=docbook2man.pl PREFIX="${EPREFIX}/usr"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" INSTALL_BIN=install install
+
+	# sys-process is more advanced than parallel from moreutils, rename it
+	if use doc; then
+		mv "${ED}"usr/share/man/man1/{,${PN}_}parallel.1 || die
+	fi
+	mv "${ED}"usr/bin/{,${PN}_}parallel || die
+}