Version bump. Remove unused localisations before processing.

(Portage version: 2.2.0_alpha118/cvs/Linux x86_64)

2 files changed, 90 insertions, 1 deletions

diff --git a/sys-boot/unetbootin/ChangeLog b/sys-boot/unetbootin/ChangeLog
index 217c36200de1..09b8d6e496dc 100644
--- a/sys-boot/unetbootin/ChangeLog
+++ b/sys-boot/unetbootin/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-boot/unetbootin
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/unetbootin/ChangeLog,v 1.82 2012/07/08 14:09:57 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/unetbootin/ChangeLog,v 1.83 2012/07/16 19:08:22 jer Exp $
+
+*unetbootin-578 (16 Jul 2012)
+
+  16 Jul 2012; Jeroen Roovers <jer@gentoo.org> +unetbootin-578.ebuild:
+  Version bump. Remove unused localisations before processing.
 
 *unetbootin-577 (08 Jul 2012)
 
diff --git a/sys-boot/unetbootin/unetbootin-578.ebuild b/sys-boot/unetbootin/unetbootin-578.ebuild
new file mode 100644
index 000000000000..9c67ec1c8298
--- /dev/null
+++ b/sys-boot/unetbootin/unetbootin-578.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/unetbootin/unetbootin-578.ebuild,v 1.1 2012/07/16 19:08:22 jer Exp $
+
+EAPI="4"
+
+inherit qt4-r2
+
+DESCRIPTION="Universal Netboot Installer creates Live USB systems for various OS
+distributions."
+HOMEPAGE="http://unetbootin.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${PN}-source-${PV}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+UNBI_LINGUAS="
+	am ar ast be bg bn ca cs da de el eo es et eu fi fo fr gl he hr hu id it ja lt
+	lv ml ms nan nb nl nn pl pt pt_BR ro ru sk sl sr sv sw tr uk ur vi zh_CN zh_TW
+"
+
+for lingua in ${UNBI_LINGUAS}; do
+	IUSE="${IUSE} linguas_${lingua}"
+done
+
+S="${WORKDIR}"
+
+DEPEND="x11-libs/qt-gui"
+RDEPEND="${DEPEND}
+		 sys-fs/mtools
+		 sys-boot/syslinux
+		 app-arch/p7zip"
+
+src_prepare() {
+	# QA check in case linguas are added or removed
+	enum() {
+		echo ${#}
+	}
+	[[ $(enum ${UNBI_LINGUAS}) -eq $(( $(enum $(echo ${PN}_*.ts) ) -1 )) ]] \
+		|| die "Numbers of recorded and actual linguas do not match"
+	unset enum
+
+	# Put all localisation file names on a single line
+	sed -i ${PN}.pro \
+		-e ':a;/unetbootin_[[:graph:]]*\.ts \\/{N;s|\\\n| |;s|    ||g;ba}' \
+		|| die
+
+	# Remove localisations
+	local lingua
+	for lingua in ${UNBI_LINGUAS}; do
+		if ! use linguas_${lingua}; then
+			sed -i ${PN}.pro -e "s| ${PN}_${lingua}.ts||g" || die
+			rm ${PN}_${lingua}.ts || die
+		fi
+	done
+}
+
+src_configure() {
+	lupdate ${PN}.pro || die
+	lrelease ${PN}.pro || die
+	eqmake4 ${PN}.pro || die
+}
+
+src_install() {
+	dobin ${PN}
+
+	insinto /usr/share/applications
+	doins ${PN}.desktop
+
+	for file in ${PN}*.png; do
+		size="${file/${PN}_}"
+		size="${size/.png}x${size/.png}"
+		insinto /usr/share/icons/hicolor/${size}/apps
+		newins ${file} ${PN}.png
+	done
+
+	local lingua
+	for lingua in ${LINGUAS}; do
+		insinto /usr/share/${PN}
+		doins ${PN}_${lingua}.qm
+	done
+}