Version bump, fixes bug #369627 and #394287 by Agostino Sarubbo <ago@gentoo.org> and Emery Hemingway <emery@vfemail.net> respectively. Add tcmalloc USE flag

(Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

2 files changed, 95 insertions, 1 deletions

diff --git a/sys-cluster/ceph/ChangeLog b/sys-cluster/ceph/ChangeLog
index b9f562e074ef..deddd53ed82b 100644
--- a/sys-cluster/ceph/ChangeLog
+++ b/sys-cluster/ceph/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for sys-cluster/ceph
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ChangeLog,v 1.15 2012/01/03 15:47:08 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ChangeLog,v 1.16 2012/01/17 17:53:08 xarthisius Exp $
+
+*ceph-0.40 (17 Jan 2012)
+
+  17 Jan 2012; Kacper Kowalik <xarthisius@gentoo.org> +ceph-0.40.ebuild:
+  Version bump, fixes bug #369627 and #394287 by Agostino Sarubbo
+  <ago@gentoo.org> and Emery Hemingway <emery@vfemail.net> respectively. Add
+  tcmalloc USE flag
 
   03 Jan 2012; Kacper Kowalik <xarthisius@gentoo.org>
   +files/ceph-issue1869.patch, -ceph-0.36.ebuild, ceph-0.38.ebuild:
diff --git a/sys-cluster/ceph/ceph-0.40.ebuild b/sys-cluster/ceph/ceph-0.40.ebuild
new file mode 100644
index 000000000000..ead4a2c4c691
--- /dev/null
+++ b/sys-cluster/ceph/ceph-0.40.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ceph-0.40.ebuild,v 1.1 2012/01/17 17:53:08 xarthisius Exp $
+
+EAPI=4
+
+inherit autotools eutils multilib
+
+DESCRIPTION="Ceph distributed filesystem"
+HOMEPAGE="http://ceph.newdream.net/"
+SRC_URI="http://ceph.newdream.net/download/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug fuse gtk libatomic radosgw static-libs tcmalloc"
+
+CDEPEND="
+	dev-libs/boost
+	dev-libs/libedit
+	dev-libs/crypto++
+	sys-apps/keyutils
+	fuse? ( sys-fs/fuse )
+	libatomic? ( dev-libs/libatomic_ops )
+	gtk? (
+			x11-libs/gtk+:2
+			dev-cpp/gtkmm:2.4
+			gnome-base/librsvg
+		)
+	radosgw? (
+				dev-libs/fcgi
+				dev-libs/expat
+			)
+	tcmalloc? ( dev-util/google-perftools )
+	"
+DEPEND="${CDEPEND}
+	dev-util/pkgconfig"
+RDEPEND="${CDEPEND}
+	sys-fs/btrfs-progs"
+
+STRIP_MASK="/usr/lib*/rados-classes/*"
+
+src_prepare() {
+	sed -e 's:invoke-rc\.d.*:/etc/init.d/ceph reload >/dev/null:' \
+		-i src/logrotate.conf || die
+	sed -i "/^docdir =/d" src/Makefile.am || die #fix doc path
+	# disable testsnaps
+	sed -e '/testsnaps/d' -i src/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--without-hadoop \
+		--docdir=/usr/share/doc/${PF} \
+		--includedir=/usr/include \
+		$(use_with debug) \
+		$(use_with fuse) \
+		$(use_with libatomic libatomic-ops) \
+		$(use_with radosgw) \
+		$(use_with gtk gtk2) \
+		$(use_enable static-libs static) \
+		$(use_with tcmalloc)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	find "${D}" -type f -name "*.la" -exec rm -f {} \;
+
+	rmdir "${D}/usr/sbin"
+
+	exeinto /usr/$(get_libdir)/ceph
+	newexe src/init-ceph ceph_init.sh
+
+	insinto /etc/logrotate.d/
+	newins src/logrotate.conf ${PN}
+
+	chmod 644 "${D}"/usr/share/doc/${PF}/sample.*
+
+	keepdir /var/lib/${PN}
+	keepdir /var/lib/${PN}/tmp
+	keepdir /var/log/${PN}/stat
+	keepdir /var/run/${PN}
+
+	newinitd "${FILESDIR}/${PN}.initd" ${PN}
+	newconfd "${FILESDIR}/${PN}.confd" ${PN}
+}