Add snapshot.

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key A792A613)

2 files changed, 68 insertions, 1 deletions

diff --git a/sys-fs/squashfs-tools/ChangeLog b/sys-fs/squashfs-tools/ChangeLog
index 1757965c5111..4cd62090d11c 100644
--- a/sys-fs/squashfs-tools/ChangeLog
+++ b/sys-fs/squashfs-tools/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-fs/squashfs-tools
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/squashfs-tools/ChangeLog,v 1.87 2012/04/24 05:42:42 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/squashfs-tools/ChangeLog,v 1.88 2012/12/17 11:44:15 jer Exp $
+
+*squashfs-tools-4.2_p20121216 (17 Dec 2012)
+
+  17 Dec 2012; Jeroen Roovers <jer@gentoo.org>
+  +squashfs-tools-4.2_p20121216.ebuild:
+  Add snapshot.
 
   24 Apr 2012; Justin Lecher <jlec@gentoo.org> -squashfs-tools-4.0.ebuild,
   -squashfs-tools-4.0-r1.ebuild, -squashfs-tools-4.1.ebuild,
diff --git a/sys-fs/squashfs-tools/squashfs-tools-4.2_p20121216.ebuild b/sys-fs/squashfs-tools/squashfs-tools-4.2_p20121216.ebuild
new file mode 100644
index 000000000000..f11f602cd923
--- /dev/null
+++ b/sys-fs/squashfs-tools/squashfs-tools-4.2_p20121216.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/squashfs-tools/squashfs-tools-4.2_p20121216.ebuild,v 1.1 2012/12/17 11:44:15 jer Exp $
+
+EAPI=4
+inherit eutils toolchain-funcs
+
+DESCRIPTION="Tool for creating compressed filesystem type squashfs"
+HOMEPAGE="http://squashfs.sourceforge.net"
+SRC_URI="
+	mirror://sourceforge/squashfs/squashfs/squashfs${PV/_p*/}.tar.gz
+	http://dev.gentoo.org/~jer/${P}.patch.bz2
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-linux"
+IUSE="+xz lzma lzo xattr"
+
+RDEPEND="
+	sys-libs/zlib
+	xz? ( app-arch/xz-utils )
+	lzo? ( dev-libs/lzo )
+	lzma? ( app-arch/xz-utils )
+	!xz? ( !lzo? ( sys-libs/zlib ) )
+	xattr? ( sys-apps/attr )"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/squashfs${PV/_p*/}/squashfs-tools"
+
+use_sed() {
+	local u=$1 s="${2:-`echo $1 | tr '[:lower:]' '[:upper:]'`}_SUPPORT"
+	printf '/^#?%s =/%s\n' "${s}" \
+		"$( use $u && echo s:.*:${s} = 1: || echo d )"
+}
+
+src_prepare() {
+	epatch "${WORKDIR}"/${P}.patch
+}
+
+src_configure() {
+	tc-export CC
+	sed -i -r \
+		-e "$(use_sed xz XZ)" \
+		-e "$(use_sed lzo)" \
+		-e "$(use_sed xattr)" \
+		-e "$(use_sed lzma LZMA_XZ)" \
+		Makefile || die
+}
+
+src_install() {
+	dobin mksquashfs unsquashfs
+	cd .. || die
+	dodoc README ACKNOWLEDGEMENTS CHANGES PERFORMANCE.README
+}
+
+pkg_postinst() {
+	ewarn "This version of mksquashfs requires a 2.6.29 kernel or better"
+	use xz &&
+		ewarn "XZ support requires a 2.6.38 kernel or better"
+}