Version bump.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

2 files changed, 92 insertions, 2 deletions

diff --git a/sys-libs/libapparmor/ChangeLog b/sys-libs/libapparmor/ChangeLog
index 1ab1cc24dbb7..db27dfdc9bdf 100644
--- a/sys-libs/libapparmor/ChangeLog
+++ b/sys-libs/libapparmor/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-libs/libapparmor
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/libapparmor/ChangeLog,v 1.2 2013/12/03 17:45:57 kensington Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/libapparmor/ChangeLog,v 1.3 2014/04/17 17:38:32 kensington Exp $
+
+*libapparmor-2.8.3 (17 Apr 2014)
+
+  17 Apr 2014; Michael Palimaka <kensington@gentoo.org>
+  +libapparmor-2.8.3.ebuild:
+  Version bump.
 
   03 Dec 2013; Michael Palimaka <kensington@gentoo.org> metadata.xml:
   Add hardened herd.
diff --git a/sys-libs/libapparmor/libapparmor-2.8.3.ebuild b/sys-libs/libapparmor/libapparmor-2.8.3.ebuild
new file mode 100644
index 000000000000..e0b40e385936
--- /dev/null
+++ b/sys-libs/libapparmor/libapparmor-2.8.3.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/libapparmor/libapparmor-2.8.3.ebuild,v 1.1 2014/04/17 17:38:32 kensington Exp $
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=1
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
+GENTOO_DEPEND_ON_PERL="no"
+
+inherit autotools-utils distutils-r1 perl-module versionator
+
+DESCRIPTION="Library to support AppArmor userspace utilities"
+HOMEPAGE="http://apparmor.net/"
+SRC_URI="http://launchpad.net/apparmor/$(get_version_component_range 1-2)/${PV}/+download/apparmor-${PV}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc +perl python static-libs"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="perl? ( dev-lang/perl:= )
+	python? ( ${PYTHON_DEPS} )"
+
+DEPEND="${RDEPEND}
+	sys-devel/autoconf-archive
+	sys-devel/bison
+	sys-devel/flex
+	doc? ( dev-lang/perl )
+	perl? ( dev-lang/swig )
+	python? ( dev-lang/swig	)"
+
+S=${WORKDIR}/apparmor-${PV}/libraries/${PN}
+
+src_prepare() {
+	rm -r m4 || die "failed to remove bundled macros"
+
+	autotools-utils_src_prepare
+	use python && distutils-r1_src_prepare
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with perl) \
+		$(use_with python)
+	)
+
+	autotools-utils_src_configure
+}
+
+src_compile() {
+	autotools-utils_src_compile -C src
+
+	use doc && autotools-utils_src_compile -C doc
+	use perl && autotools-utils_src_compile -C swig/perl
+
+	if use python ; then
+		pushd "${BUILD_DIR}"/swig/python > /dev/null
+		emake libapparmor_wrap.c
+		distutils-r1_src_compile
+		popd > /dev/null
+	fi
+}
+
+src_install() {
+	autotools-utils_src_install -C src
+	use doc && autotools-utils_src_install -C doc
+
+	if use perl ; then
+		autotools-utils_src_install -C swig/perl
+		perlinfo
+		insinto "${VENDOR_ARCH}"
+		doins "${BUILD_DIR}"/swig/perl/LibAppArmor.pm
+	fi
+
+	if use python ; then
+		pushd "${BUILD_DIR}"/swig/python > /dev/null
+		distutils-r1_src_install
+		popd > /dev/null
+	fi
+}