Add a revision that uses xulrunner-1.9, also solves bug 213361

(Portage version: 2.1.5.6)

3 files changed, 92 insertions, 1 deletions

diff --git a/www-client/epiphany/ChangeLog b/www-client/epiphany/ChangeLog
index 0f969810baef..531ded40a985 100644
--- a/www-client/epiphany/ChangeLog
+++ b/www-client/epiphany/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for www-client/epiphany
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v 1.158 2008/06/02 22:57:09 leio Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v 1.159 2008/06/19 16:59:46 leio Exp $
+
+*epiphany-2.22.2-r10 (19 Jun 2008)
+
+  19 Jun 2008; Mart Raudsepp <leio@gentoo.org>
+  +files/epiphany-2.22.2-xul1.9-ContentHandler-fix.patch,
+  +epiphany-2.22.2-r10.ebuild:
+  Add a revision that uses xulrunner-1.9, also solves bug 213361
 
   02 Jun 2008; Mart Raudsepp <leio@gentoo.org> epiphany-2.22.1.1.ebuild,
   epiphany-2.22.2.ebuild:
diff --git a/www-client/epiphany/epiphany-2.22.2-r10.ebuild b/www-client/epiphany/epiphany-2.22.2-r10.ebuild
new file mode 100644
index 000000000000..dd176bc5af8a
--- /dev/null
+++ b/www-client/epiphany/epiphany-2.22.2-r10.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/epiphany-2.22.2-r10.ebuild,v 1.1 2008/06/19 16:59:46 leio Exp $
+
+inherit gnome2 eutils multilib
+
+DESCRIPTION="GNOME webbrowser based on the mozilla rendering engine"
+HOMEPAGE="http://www.gnome.org/projects/epiphany/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="avahi doc networkmanager python spell"
+
+# This revision is meant to work with xulrunner 1.9, an earlier revision
+# is the earlier stable candidate against xulrunner-1.8 and co.
+
+RDEPEND=">=dev-libs/glib-2.16.0
+	>=x11-libs/gtk+-2.12.0
+	>=dev-libs/libxml2-2.6.12
+	>=dev-libs/libxslt-1.1.7
+	>=gnome-base/libglade-2.3.1
+	>=gnome-base/libgnome-2.14
+	>=gnome-base/libgnomeui-2.14
+	>=gnome-base/gnome-desktop-2.9.91
+	>=x11-libs/startup-notification-0.5
+	>=x11-libs/libnotify-0.4
+	>=dev-libs/dbus-glib-0.71
+	>=gnome-base/gconf-2
+	>=app-text/iso-codes-0.35
+	avahi? ( >=net-dns/avahi-0.6.22 )
+	networkmanager? ( net-misc/networkmanager )
+	=net-libs/xulrunner-1.9*
+	python? (
+		>=dev-lang/python-2.3
+		>=dev-python/pygtk-2.7.1
+		>=dev-python/gnome-python-2.6
+	)
+	x11-themes/gnome-icon-theme"
+DEPEND="${RDEPEND}
+	app-text/scrollkeeper
+	>=dev-util/pkgconfig-0.9
+	>=dev-util/intltool-0.35
+	>=app-text/gnome-doc-utils-0.3.2
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS README TODO"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-scrollkeeper
+		--with-gecko=libxul-embedding
+		--enable-certificate-manager
+		--with-distributor-name=Gentoo
+		$(use_enable avahi zeroconf)
+		$(use_enable networkmanager network-manager)
+		$(use_enable spell spell-checker)
+		$(use_enable python)"
+}
+
+src_unpack() {
+	gnome2_src_unpack
+	epatch "${FILESDIR}/${P}-xul1.9-ContentHandler-fix.patch"
+}
+
+src_compile() {
+	addpredict /usr/$(get_libdir)/xulrunner-1.9/components/xpti.dat
+	addpredict /usr/$(get_libdir)/xulrunner-1.9/components/xpti.dat.tmp
+	addpredict /usr/$(get_libdir)/xulrunner-1.9/components/compreg.dat.tmp
+
+	gnome2_src_compile
+}
diff --git a/www-client/epiphany/files/epiphany-2.22.2-xul1.9-ContentHandler-fix.patch b/www-client/epiphany/files/epiphany-2.22.2-xul1.9-ContentHandler-fix.patch
new file mode 100644
index 000000000000..356bd7fb319d
--- /dev/null
+++ b/www-client/epiphany/files/epiphany-2.22.2-xul1.9-ContentHandler-fix.patch
@@ -0,0 +1,12 @@
+--- branches/gnome-2-22/embed/mozilla/ContentHandler.cpp	2008/06/12 17:21:16	8278
++++ branches/gnome-2-22/embed/mozilla/ContentHandler.cpp	2008/06/13 00:36:19	8279
+@@ -135,6 +135,9 @@
+ 				    nsISupports *aWindowContext,
+ 				    const PRUnichar *aDefaultFile,
+ 				    const PRUnichar *aSuggestedFileExtension,
++#ifdef HAVE_GECKO_1_9
++				    PRBool aForcePrompt,
++#endif
+ 				    nsILocalFile **_retval)
+ {
+ 	EphyFileChooser *dialog;