Version bump. Remove old. This should fix bug #303080 by Oschtan <dawnstyle@gmail.com>.

(Portage version: 2.1.8.3/cvs/Linux i686)

4 files changed, 73 insertions, 132 deletions

diff --git a/www-client/chromium-bin/ChangeLog b/www-client/chromium-bin/ChangeLog
index 70591608973f..59dfe3137c99 100644
--- a/www-client/chromium-bin/ChangeLog
+++ b/www-client/chromium-bin/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for www-client/chromium-bin
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium-bin/ChangeLog,v 1.76 2010/09/17 01:13:44 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium-bin/ChangeLog,v 1.77 2010/10/09 14:20:52 phajdan.jr Exp $
+
+*chromium-bin-6.0.472.62 (09 Oct 2010)
+
+  09 Oct 2010; Pawel Hajdan jr <phajdan.jr@gentoo.org>
+  -chromium-bin-6.0.470.0_p52843.ebuild, +chromium-bin-6.0.472.62.ebuild:
+  Version bump. Remove old. This should fix bug #303080 by Oschtan
+  <dawnstyle@gmail.com>.
 
   17 Sep 2010; Pawel Hajdan jr <phajdan.jr@gentoo.org>
   chromium-bin-6.0.472.51.ebuild:
diff --git a/www-client/chromium-bin/chromium-bin-6.0.470.0_p52843.ebuild b/www-client/chromium-bin/chromium-bin-6.0.470.0_p52843.ebuild
deleted file mode 100644
index 819387995093..000000000000
--- a/www-client/chromium-bin/chromium-bin-6.0.470.0_p52843.ebuild
+++ /dev/null
@@ -1,127 +0,0 @@
-# Copyright 1999-2010 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium-bin/chromium-bin-6.0.470.0_p52843.ebuild,v 1.1 2010/07/19 08:21:57 voyageur Exp $
-
-EAPI="2"
-inherit eutils multilib portability
-
-# Latest revision id can be found at
-# http://build.chromium.org/buildbot/snapshots/chromium-rel-linux/LATEST
-MY_PV="${PV/[0-9.]*\_p}"
-
-DESCRIPTION="Open-source version of Google Chrome web browser (binary version)"
-HOMEPAGE="http://code.google.com/chromium/"
-SRC_URI="x86? ( http://build.chromium.org/buildbot/snapshots/chromium-rel-linux/${MY_PV}/chrome-linux.zip -> ${PN}-x86-${MY_PV}.zip )
-	amd64? ( http://build.chromium.org/buildbot/snapshots/chromium-rel-linux-64/${MY_PV}/chrome-linux.zip -> ${PN}-amd64-${MY_PV}.zip )"
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="-* ~amd64 ~x86"
-IUSE="+plugins-symlink"
-
-DEPEND="app-arch/unzip"
-RDEPEND="app-arch/bzip2
-	>=dev-libs/nspr-4.7
-	>=dev-libs/nss-3.12.3
-	>=gnome-base/gconf-2.24.0
-	>=media-libs/alsa-lib-1.0.19
-	<media-libs/jpeg-7
-	=media-libs/libpng-1.2*
-	>=net-print/cups-1.3.5
-	>=sys-devel/gcc-4.2
-	sys-libs/zlib
-	>=x11-libs/gtk+-2.14.7
-	x11-libs/libXScrnSaver
-	x11-misc/xdg-utils
-	virtual/ttf-fonts
-	|| (
-		x11-themes/gnome-icon-theme
-		x11-themes/oxygen-molecule
-		x11-themes/tango-icon-theme
-		x11-themes/xfce4-icon-theme
-	)"
-
-S=${WORKDIR}
-
-QA_EXECSTACK="opt/chromium.org/chrome-linux/chrome"
-
-# Ogg/Theora/Vorbis-only FFmpeg binaries
-QA_TEXTRELS="opt/chromium.org/chrome-linux/libffmpegsumo.so"
-QA_PRESTRIPPED="opt/chromium.org/chrome-linux/libffmpegsumo.so"
-
-pkg_setup() {
-	if [[ "${ROOT}" == "/" ]]; then
-		# Built with SSE2 enabled, so will fail on older processors
-		if ! grep -q sse2 /proc/cpuinfo; then
-			die "This binary requires SSE2 support, it will not work on older processors"
-		fi
-
-		# Prevent user problems like bug 299777.
-		if ! grep -q /dev/shm <<< $(get_mounts); then
-			eerror "You don't have tmpfs mounted at /dev/shm."
-			eerror "${PN} isn't going to work in that configuration."
-			eerror "Please uncomment the /dev/shm entry in /etc/fstab,"
-			eerror "run 'mount /dev/shm' and try again."
-			die "/dev/shm is not mounted"
-		fi
-		if [ `stat -c %a /dev/shm` -ne 1777 ]; then
-			eerror "/dev/shm does not have correct permissions."
-			eerror "${PN} isn't going to work in that configuration."
-			eerror "Please run chmod 1777 /dev/shm and try again."
-			die "/dev/shm has incorrect permissions"
-		fi
-	fi
-}
-
-src_install() {
-	declare CHROMIUM_HOME=/opt/chromium.org
-
-	dodir ${CHROMIUM_HOME}
-	cp -R chrome-linux/ "${D}"${CHROMIUM_HOME} || die "Unable to install chrome-linux folder"
-
-	# Man page (rename to prevent collision with chromium)
-	newman chrome-linux/chrome.1 chromium-bin.1
-	rm "${D}"${CHROMIUM_HOME}/chrome-linux/chrome.1
-
-	# Plugins symlink, optional wrt bug #301911
-	if use plugins-symlink; then
-		dosym /usr/$(get_libdir)/nsbrowser/plugins ${CHROMIUM_HOME}/chrome-linux/plugins
-	fi
-
-	# Create symlinks for needed libraries
-	dodir ${CHROMIUM_HOME}/nss-nspr
-	if has_version ">=dev-libs/nss-3.12.5-r1"; then
-		NSS_DIR=/usr/$(get_libdir)
-	else
-		NSS_DIR=/usr/$(get_libdir)/nss
-	fi
-	if has_version ">=dev-libs/nspr-4.8.3-r2"; then
-		NSPR_DIR=/usr/$(get_libdir)
-	else
-		NSPR_DIR=/usr/$(get_libdir)/nspr
-	fi
-
-	dosym ${NSPR_DIR}/libnspr4.so ${CHROMIUM_HOME}/nss-nspr/libnspr4.so.0d
-	dosym ${NSPR_DIR}/libplc4.so ${CHROMIUM_HOME}/nss-nspr/libplc4.so.0d
-	dosym ${NSPR_DIR}/libplds4.so ${CHROMIUM_HOME}/nss-nspr/libplds4.so.0d
-	dosym ${NSS_DIR}/libnss3.so ${CHROMIUM_HOME}/nss-nspr/libnss3.so.1d
-	dosym ${NSS_DIR}/libnssutil3.so ${CHROMIUM_HOME}/nss-nspr/libnssutil3.so.1d
-	dosym ${NSS_DIR}/libsmime3.so ${CHROMIUM_HOME}/nss-nspr/libsmime3.so.1d
-	dosym ${NSS_DIR}/libssl3.so ${CHROMIUM_HOME}/nss-nspr/libssl3.so.1d
-
-	# Create chromium-bin wrapper
-	make_wrapper chromium-bin ./chrome ${CHROMIUM_HOME}/chrome-linux ${CHROMIUM_HOME}/nss-nspr:${CHROMIUM_HOME}/chrome-linux
-	newicon "${FILESDIR}"/chromium.png ${PN}.png
-	make_desktop_entry chromium-bin "Chromium (bin)" ${PN} "Network;WebBrowser"
-	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop \
-		|| die "desktop file sed failed"
-}
-
-pkg_postinst() {
-	ewarn "This binary requires the C++ runtime from >=sys-devel/gcc-4.2"
-	ewarn "If you get the \"version \`GLIBCXX_3.4.9' not found\" error message,"
-	ewarn "switch your active gcc to a version >=4.2 with gcc-config"
-	if [[ ${ROOT} != "/" ]]; then
-		ewarn "This package will not work on processors without SSE2 instruction"
-		ewarn "set support (Intel Pentium III/AMD Athlon or older)."
-	fi
-}
diff --git a/www-client/chromium-bin/chromium-bin-6.0.472.62.ebuild b/www-client/chromium-bin/chromium-bin-6.0.472.62.ebuild
new file mode 100644
index 000000000000..16485e5fe6b3
--- /dev/null
+++ b/www-client/chromium-bin/chromium-bin-6.0.472.62.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium-bin/chromium-bin-6.0.472.62.ebuild,v 1.1 2010/10/09 14:20:59 phajdan.jr Exp $
+
+EAPI="2"
+inherit eutils multilib
+
+DESCRIPTION="Open-source version of Google Chrome web browser (binary version)"
+HOMEPAGE="http://code.google.com/chromium/"
+SRC_URI="x86? ( mirror://gentoo/${PN}-x86-${PV}.tar.bz2 )
+	amd64? ( mirror://gentoo/${PN}-amd64-${PV}.tar.bz2 )"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE=""
+
+DEPEND=""
+RDEPEND="app-arch/bzip2
+	dev-libs/dbus-glib
+	dev-libs/expat
+	dev-libs/glib
+	>=dev-libs/libevent-1.4.13
+	>=dev-libs/nspr-4.7
+	>=dev-libs/nss-3.12.3
+	>=gnome-base/gconf-2.24.0
+	>=gnome-base/gnome-keyring-2.28.2
+	>=media-libs/alsa-lib-1.0.19
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/jpeg:0
+	=media-libs/libpng-1.4*
+	>=net-print/cups-1.4.4
+	sys-apps/dbus
+	>=sys-libs/glibc-2.11.2
+	sys-libs/zlib
+	x11-apps/xmessage
+	x11-libs/cairo
+	>=x11-libs/gtk+-2.14.7
+	x11-libs/libXScrnSaver
+	x11-libs/pango
+	x11-misc/xdg-utils
+	virtual/ttf-fonts
+	|| (
+		x11-themes/gnome-icon-theme
+		x11-themes/oxygen-molecule
+		x11-themes/tango-icon-theme
+		x11-themes/xfce4-icon-theme
+	)"
+
+get_chromium_home() {
+	echo "/opt/chromium.org"
+}
+
+src_install() {
+	dodir "$(get_chromium_home)" || die
+	insinto "$(get_chromium_home)"
+	cp -R usr/$(get_libdir)/chromium-browser/* "${D}/$(get_chromium_home)" || die
+
+	make_wrapper chromium-bin ./chrome "$(get_chromium_home)"
+	newicon "${FILESDIR}"/chromium.png ${PN}.png
+	make_desktop_entry chromium-bin "Chromium (bin)" ${PN} "Network;WebBrowser"
+	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop \
+		|| die "desktop file sed failed"
+}
diff --git a/www-client/chromium-bin/metadata.xml b/www-client/chromium-bin/metadata.xml
index 326572ae0b39..e9579fd9c444 100644
--- a/www-client/chromium-bin/metadata.xml
+++ b/www-client/chromium-bin/metadata.xml
@@ -2,8 +2,5 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 	<herd>chromium</herd>
-	<longdescription>Chromium is the open-source web browser project behind Google Chrome. This is a binary version, grabbed from chromium buildbot</longdescription>
-	<use>
-		<flag name='plugins-symlink'>Add support for system web browser plugins out of the box</flag>
-	</use>
+	<longdescription>Chromium is the open-source web browser project behind Google Chrome.</longdescription>
 </pkgmetadata>