Version bump.

(Portage version: 2.2.0_alpha144/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

2 files changed, 75 insertions, 1 deletions

diff --git a/xfce-base/thunar/ChangeLog b/xfce-base/thunar/ChangeLog
index d8d692060744..a6fcb9e3d219 100644
--- a/xfce-base/thunar/ChangeLog
+++ b/xfce-base/thunar/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for xfce-base/thunar
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/ChangeLog,v 1.152 2012/12/02 22:15:33 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/ChangeLog,v 1.153 2012/12/10 07:47:54 ssuominen Exp $
+
+*thunar-1.6.1 (10 Dec 2012)
+
+  10 Dec 2012; Samuli Suominen <ssuominen@gentoo.org> +thunar-1.6.1.ebuild:
+  Version bump.
 
   02 Dec 2012; Samuli Suominen <ssuominen@gentoo.org> thunar-1.4.0.ebuild:
   Use virtual/udev instead of sys-fs/udev wrt #444398
diff --git a/xfce-base/thunar/thunar-1.6.1.ebuild b/xfce-base/thunar/thunar-1.6.1.ebuild
new file mode 100644
index 000000000000..388ceb0826f3
--- /dev/null
+++ b/xfce-base/thunar/thunar-1.6.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/thunar-1.6.1.ebuild,v 1.1 2012/12/10 07:47:54 ssuominen Exp $
+
+EAPI=5
+inherit virtualx xfconf
+
+MY_P=${P/t/T}
+
+DESCRIPTION="File manager for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/ http://thunar.xfce.org/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="+dbus debug exif libnotify pcre startup-notification test +xfce_plugins_trash udev"
+
+GVFS_DEPEND=">=gnome-base/gvfs-1.10.1"
+COMMON_DEPEND=">=dev-lang/perl-5.6
+	>=dev-libs/glib-2.30
+	>=x11-libs/gdk-pixbuf-2.14
+	>=x11-libs/gtk+-2.24:2
+	>=xfce-base/exo-0.10
+	>=xfce-base/libxfce4ui-4.10
+	>=xfce-base/libxfce4util-4.10
+	>=xfce-base/xfconf-4.10
+	dbus? ( >=dev-libs/dbus-glib-0.100 )
+	exif? ( >=media-libs/libexif-0.6.19 )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	pcre? ( >=dev-libs/libpcre-6 )
+	startup-notification? ( x11-libs/startup-notification )
+	udev? ( virtual/udev[gudev] )
+	xfce_plugins_trash? ( >=xfce-base/xfce4-panel-4.10 )"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-util/desktop-file-utils-0.20-r1
+	x11-misc/shared-mime-info
+	dbus? ( ${GVFS_DEPEND} )
+	udev? ( || ( ${GVFS_DEPEND}[udisks,udev] ${GVFS_DEPEND}[gdu,udev] ) )
+	xfce_plugins_trash? ( ${GVFS_DEPEND} )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+REQUIRED_USE="xfce_plugins_trash? ( dbus )"
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable dbus)
+		$(use_enable startup-notification)
+		$(use_enable udev gudev)
+		$(use_enable libnotify notifications)
+		$(xfconf_use_debug)
+		$(use_enable exif)
+		$(use_enable pcre)
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+		)
+
+	use xfce_plugins_trash || XFCONF+=( --disable-tpa-plugin )
+
+	DOCS=( AUTHORS ChangeLog FAQ HACKING NEWS README THANKS TODO )
+}
+
+src_test() {
+	Xemake check
+}