Support x11-misc/alock in the xflock4 script wrt #501370 by Jesús Guerrero

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

3 files changed, 87 insertions, 1 deletions

diff --git a/xfce-base/xfce4-session/ChangeLog b/xfce-base/xfce4-session/ChangeLog
index c073dc8ca694..0ba02bdfab27 100644
--- a/xfce-base/xfce4-session/ChangeLog
+++ b/xfce-base/xfce4-session/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for xfce-base/xfce4-session
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/ChangeLog,v 1.188 2014/01/28 14:17:20 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/ChangeLog,v 1.189 2014/03/05 11:50:18 ssuominen Exp $
+
+*xfce4-session-4.10.1-r1 (05 Mar 2014)
+
+  05 Mar 2014; Samuli Suominen <ssuominen@gentoo.org>
+  +files/xfce4-session-4.10.1-alock_support_to_xflock4.patch,
+  +xfce4-session-4.10.1-r1.ebuild:
+  Support x11-misc/alock in the xflock4 script wrt #501370 by Jesús Guerrero
 
   28 Jan 2014; Agostino Sarubbo <ago@gentoo.org> xfce4-session-4.10.1.ebuild:
   Stable for x86, wrt bug #496018
diff --git a/xfce-base/xfce4-session/files/xfce4-session-4.10.1-alock_support_to_xflock4.patch b/xfce-base/xfce4-session/files/xfce4-session-4.10.1-alock_support_to_xflock4.patch
new file mode 100644
index 000000000000..feb020aaff03
--- /dev/null
+++ b/xfce-base/xfce4-session/files/xfce4-session-4.10.1-alock_support_to_xflock4.patch
@@ -0,0 +1,15 @@
+http://bugs.gentoo.org/501370
+http://bugzilla.xfce.org/show_bug.cgi?id=10679
+
+--- scripts/xflock4
++++ scripts/xflock4
+@@ -35,7 +35,8 @@
+ # else run another access locking utility, if installed
+ for lock_cmd in \
+   "xlock -mode blank" \
+-  "slock"
++  "slock" \
++  "alock -bg blank -auth pam"
+   do
+     set -- $lock_cmd
+     if command -v -- $1 >/dev/null 2>&1; then
diff --git a/xfce-base/xfce4-session/xfce4-session-4.10.1-r1.ebuild b/xfce-base/xfce4-session/xfce4-session-4.10.1-r1.ebuild
new file mode 100644
index 000000000000..a7f16f87eb06
--- /dev/null
+++ b/xfce-base/xfce4-session/xfce4-session-4.10.1-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/xfce4-session-4.10.1-r1.ebuild,v 1.1 2014/03/05 11:50:18 ssuominen Exp $
+
+EAPI=5
+inherit xfconf
+
+DESCRIPTION="A session manager for the Xfce desktop environment"
+HOMEPAGE="http://docs.xfce.org/xfce/xfce4-session/start"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug systemd udev +xscreensaver"
+
+COMMON_DEPEND=">=dev-libs/dbus-glib-0.100
+	x11-apps/iceauth
+	x11-libs/libSM
+	>=x11-libs/libwnck-2.30:1
+	x11-libs/libX11
+	>=xfce-base/libxfce4util-4.10.1
+	>=xfce-base/libxfce4ui-4.10
+	>=xfce-base/xfconf-4.10
+	!xfce-base/xfce-utils
+	systemd? ( >=sys-auth/polkit-0.100 )"
+RDEPEND="${COMMON_DEPEND}
+	x11-apps/xrdb
+	x11-misc/xdg-user-dirs
+	udev? ( >=sys-power/upower-0.9.20 )
+	xscreensaver? ( || (
+		>=x11-misc/xscreensaver-5.26
+		gnome-extra/gnome-screensaver
+		>=x11-misc/xlockmore-5.43
+		x11-misc/slock
+		x11-misc/alock
+		) )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+pkg_setup() {
+	PATCHES=( "${FILESDIR}"/${P}-alock_support_to_xflock4.patch )
+
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable systemd)
+		--with-xsession-prefix="${EPREFIX}"/usr
+		$(xfconf_use_debug)
+		)
+
+	DOCS=( AUTHORS BUGS ChangeLog NEWS README TODO )
+}
+
+src_install() {
+	xfconf_src_install
+
+	local sessiondir=/etc/X11/Sessions
+	echo startxfce4 > "${T}"/Xfce4
+	exeinto ${sessiondir}
+	doexe "${T}"/Xfce4
+	dosym Xfce4 ${sessiondir}/Xfce
+}