Version Bump

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0x7EF137EC935B0EAF)

2 files changed, 78 insertions, 1 deletions

diff --git a/xfce-base/thunar/ChangeLog b/xfce-base/thunar/ChangeLog
index 056ff75d1ab9..17aa25c15379 100644
--- a/xfce-base/thunar/ChangeLog
+++ b/xfce-base/thunar/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for xfce-base/thunar
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/ChangeLog,v 1.177 2015/03/08 15:06:39 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/ChangeLog,v 1.178 2015/04/20 17:01:56 perfinion Exp $
+
+*thunar-1.6.7 (20 Apr 2015)
+
+  20 Apr 2015; Jason Zaman <perfinion@gentoo.org> +thunar-1.6.7.ebuild:
+  Version Bump
 
 *thunar-1.6.6 (08 Mar 2015)
 
diff --git a/xfce-base/thunar/thunar-1.6.7.ebuild b/xfce-base/thunar/thunar-1.6.7.ebuild
new file mode 100644
index 000000000000..fcc0315252d1
--- /dev/null
+++ b/xfce-base/thunar/thunar-1.6.7.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/thunar-1.6.7.ebuild,v 1.1 2015/04/20 17:01:56 perfinion Exp $
+
+EAPI=5
+inherit virtualx xfconf
+
+MY_P=${P/t/T}
+
+DESCRIPTION="File manager for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/ http://thunar.xfce.org/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="+dbus debug exif libnotify pcre startup-notification test udisks +xfce_plugins_trash"
+
+GVFS_DEPEND=">=gnome-base/gvfs-1.18.3"
+COMMON_DEPEND=">=dev-lang/perl-5.6
+	>=dev-libs/glib-2.30
+	>=x11-libs/gdk-pixbuf-2.14
+	>=x11-libs/gtk+-2.24:2
+	>=xfce-base/exo-0.10
+	>=xfce-base/libxfce4ui-4.10
+	>=xfce-base/libxfce4util-4.10.1
+	>=xfce-base/xfconf-4.10
+	dbus? ( >=dev-libs/dbus-glib-0.100 )
+	exif? ( >=media-libs/libexif-0.6.19 )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	pcre? ( >=dev-libs/libpcre-6 )
+	startup-notification? ( x11-libs/startup-notification )
+	udisks? ( virtual/libgudev:= )
+	xfce_plugins_trash? ( >=xfce-base/xfce4-panel-4.10 )"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-util/desktop-file-utils-0.20-r1
+	x11-misc/shared-mime-info
+	dbus? ( ${GVFS_DEPEND} )
+	udisks? (
+		virtual/udev
+		${GVFS_DEPEND}[udisks,udev]
+		)
+	xfce_plugins_trash? ( ${GVFS_DEPEND} )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+REQUIRED_USE="xfce_plugins_trash? ( dbus )"
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable dbus)
+		$(use_enable startup-notification)
+		$(use_enable udisks gudev)
+		$(use_enable libnotify notifications)
+		$(xfconf_use_debug)
+		$(use_enable exif)
+		$(use_enable pcre)
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+		)
+
+	use xfce_plugins_trash || XFCONF+=( --disable-tpa-plugin )
+
+	DOCS=( AUTHORS ChangeLog FAQ HACKING NEWS README THANKS TODO )
+}
+
+src_test() {
+	Xemake check
+}