1 files changed, 67 insertions, 0 deletions
diff --git a/app-misc/mc/mc-4.7.0_pre2-r1.ebuild b/app-misc/mc/mc-4.7.0_pre2-r1.ebuild
new file mode 100644
index 000000000000..cfd6e1a4e733
--- /dev/null
+++ b/app-misc/mc/mc-4.7.0_pre2-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/mc-4.7.0_pre2-r1.ebuild,v 1.1 2009/09/04 13:05:24 ssuominen Exp $
+
+EAPI=2
+MY_P=${P/_/-}
+inherit eutils
+
+DESCRIPTION="GNU Midnight Commander is a text based file manager"
+HOMEPAGE="http://www.midnight-commander.org"
+SRC_URI="http://www.midnight-commander.org/downloads/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="chdir +edit gpm nls samba slang X"
+
+RDEPEND=">=dev-libs/glib-2.6:2
+	gpm? ( sys-libs/gpm )
+	kernel_linux? ( sys-fs/e2fsprogs )
+	samba? ( net-fs/samba )
+	slang? ( >=sys-libs/slang-2 )
+	!slang? ( sys-libs/ncurses )
+	X? ( x11-libs/libX11
+		x11-libs/libICE
+		x11-libs/libXau
+		x11-libs/libXdmcp
+		x11-libs/libSM )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-horizontal_split.patch
+}
+
+src_configure() {
+	local myscreen=ncurses
+
+	use slang && myscreen=slang
+
+	econf \
+		--disable-dependency-tracking \
+		$(use_enable nls) \
+		--enable-vfs \
+		$(use_enable kernel_linux vfs-undelfs) \
+		--enable-charset \
+		$(use_with X x) \
+		$(use_with samba) \
+		--with-configdir=/etc/samba \
+		--with-codepagedir=/var/lib/samba/codepages \
+		$(use_with gpm gpm-mouse) \
+		--with-screen=${myscreen} \
+		$(use_with edit)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS NEWS README
+
+	if use chdir; then
+		insinto /etc/profile.d
+		doins "${FILESDIR}"/mc-chdir.sh
+	fi
+}