1 files changed, 64 insertions, 0 deletions
diff --git a/gnome-extra/hamster-applet/hamster-applet-2.26.3.ebuild b/gnome-extra/hamster-applet/hamster-applet-2.26.3.ebuild
new file mode 100644
index 000000000000..0cfecef3e73c
--- /dev/null
+++ b/gnome-extra/hamster-applet/hamster-applet-2.26.3.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/hamster-applet/hamster-applet-2.26.3.ebuild,v 1.1 2009/07/16 23:20:19 eva Exp $
+
+EAPI="2"
+GCONF_DEBUG="no"
+SCROLLKEEPER_UPDATE="no"
+
+inherit eutils gnome2 python
+
+DESCRIPTION="Time tracking for the masses, in a GNOME applet"
+HOMEPAGE="http://projecthamster.wordpress.com/"
+
+# license on homepage is out-of-date, was changed to GPL-2 on 2008-04-16
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="eds libnotify"
+
+RDEPEND=">=dev-lang/python-2.4
+	|| (
+		>=dev-lang/python-2.5[sqlite]
+		dev-python/pysqlite:2 )
+	dev-python/gconf-python
+	dev-python/libgnome-python
+	dev-python/gnome-applets-python
+	dev-python/dbus-python
+	eds? ( dev-python/evolution-python )
+	libnotify? ( dev-python/notify-python )
+	>=dev-python/pygobject-2.14
+	>=dev-python/pygtk-2.12
+	>=x11-libs/gtk+-2.12
+	x11-libs/libXScrnSaver"
+
+DEPEND="${RDEPEND}
+	x11-proto/scrnsaverproto
+	>=dev-util/intltool-0.40
+	dev-util/pkgconfig
+	sys-devel/gettext"
+
+DOCS="AUTHORS ChangeLog NEWS README"
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# disable pyc compiling
+	mv py-compile py-compile.orig
+	ln -s $(type -P true) py-compile
+
+	# Fix intltoolize broken file, see upstream #577133
+	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in || die "sed failed"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	python_need_rebuild
+	python_mod_optimize $(python_get_sitedir)/hamster
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+	python_mod_cleanup /usr/$(get_libdir)/python*/site-packages/hamster
+}