1 files changed, 47 insertions, 0 deletions
diff --git a/net-misc/libupnp/libupnp-1.4.4-r1.ebuild b/net-misc/libupnp/libupnp-1.4.4-r1.ebuild
new file mode 100644
index 000000000000..6d5111b6d86f
--- /dev/null
+++ b/net-misc/libupnp/libupnp-1.4.4-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/libupnp/libupnp-1.4.4-r1.ebuild,v 1.1 2007/04/19 13:10:16 gurligebis Exp $
+
+WANT_AUTOMAKE=1.9
+
+inherit eutils flag-o-matic autotools
+
+DESCRIPTION="An Portable Open Source UPnP Development Kit"
+HOMEPAGE="http://pupnp.sourceforge.net/"
+SRC_URI="mirror://sourceforge/pupnp/${P}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug"
+
+RDEPEND="!net-misc/upnp"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}"/${PN}-${PVR}-fbsd.patch
+
+	AT_M4DIR="m4" eautoreconf
+
+	# fix tests
+	chmod +x ixml/test/test_document.sh
+}
+
+src_compile() {
+	use x86-fbsd &&	replace-flags -O? -O1
+	# w/o docdir to avoid sandbox violations	
+	econf \
+		$(use_enable debug) \
+		--without-docdir \
+		|| die "econf failed"
+	emake || die "emake failed"
+}
+
+src_install () {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dobin upnp/.libs/upnp_tv_{ctrlpt,device}
+	dodoc NEWS README ChangeLog
+	dohtml upnp/doc/*.pdf
+}