1 files changed, 52 insertions, 0 deletions
diff --git a/sys-devel/automake/automake-1.7.9-r1.ebuild b/sys-devel/automake/automake-1.7.9-r1.ebuild
new file mode 100644
index 000000000000..dca41080ead0
--- /dev/null
+++ b/sys-devel/automake/automake-1.7.9-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/automake/automake-1.7.9-r1.ebuild,v 1.1 2005/01/29 07:12:33 vapier Exp $
+
+inherit eutils gnuconfig
+
+DESCRIPTION="Used to generate Makefile.in from Makefile.am"
+HOMEPAGE="http://sources.redhat.com/automake/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="${PV:0:3}"
+KEYWORDS="~alpha amd64 arm hppa ia64 ~mips ~ppc ~ppc64 s390 sh ~sparc x86"
+IUSE="uclibc"
+
+DEPEND="dev-lang/perl
+	sys-devel/automake-wrapper
+	>=sys-devel/autoconf-2.59-r6
+	sys-devel/gnuconfig"
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}
+	sed -i \
+		-e "/^@setfilename/s|automake|automake${SLOT}|" \
+		-e "s|automake: (automake)|automake v${SLOT}: (automake${SLOT})|" \
+		-e "s|aclocal: (automake)|aclocal v${SLOT}: (automake${SLOT})|" \
+		automake.texi || die "sed failed"
+	epatch ${FILESDIR}/${P}-infopage-namechange.patch
+	gnuconfig_update
+	export WANT_AUTOCONF=2.5
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die
+	rm -f "${D}"/usr/bin/{aclocal,automake}
+
+	dodoc NEWS README THANKS TODO AUTHORS ChangeLog
+	mv "${D}"/usr/share/info/automake{,${SLOT}}.info
+
+	# remove all config.guess and config.sub files replacing them
+	# w/a symlink to a specific gnuconfig version
+	local x=
+	for x in guess sub ; do
+		dosym ../gnuconfig/config.${x} /usr/share/${PN}-${SLOT}/config.${x}
+	done
+}
+
+pkg_postinst() {
+	einfo "Please note that the 'WANT_AUTOMAKE_1_7=1' syntax has changed to:"
+	einfo "  WANT_AUTOMAKE=1.7"
+}