1 files changed, 64 insertions, 0 deletions
diff --git a/x11-misc/pcmanfm/pcmanfm-0.5.1-r1.ebuild b/x11-misc/pcmanfm/pcmanfm-0.5.1-r1.ebuild
new file mode 100644
index 000000000000..3f1e7f70535f
--- /dev/null
+++ b/x11-misc/pcmanfm/pcmanfm-0.5.1-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/pcmanfm/pcmanfm-0.5.1-r1.ebuild,v 1.1 2009/10/25 03:12:02 vostorga Exp $
+
+EAPI="2"
+inherit autotools eutils fdo-mime
+
+DESCRIPTION="Extremely fast and lightweight tabbed file manager"
+HOMEPAGE="http://pcmanfm.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="hal"
+
+RDEPEND="virtual/fam
+	x11-libs/cairo
+	x11-libs/gtk+:2
+	x11-misc/shared-mime-info
+	x11-themes/gnome-icon-theme
+	x11-libs/startup-notification
+	hal? ( sys-apps/hal )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	sys-devel/gettext"
+
+src_prepare() {
+	# Don't break Gnome & possibly other environments, bug 272318
+	epatch "${FILESDIR}"/pcmanfm-find.desktop.patch
+	epatch "${FILESDIR}"/${P}-shared-mime-info-0.70.patch
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable hal)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS ChangeLog NEWS README TODO || die "dodoc failed"
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+
+	if has_version app-admin/fam ; then
+		elog "You are using fam as your file alteration monitor,"
+		elog "so you must have famd started before running pcmanfm."
+		elog
+		elog "To add famd to the default runlevel and start it, run:"
+		elog
+		elog "# rc-update add famd default"
+		elog "# /etc/init.d/famd start"
+		elog
+		elog "It is recommended you use gamin instead of fam."
+	fi
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}