app-admin/elektra/elektra-0.8.3-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/elektra/elektra-0.8.3-r2.ebuild,v 1.1 2013/04/22 14:17:35 xmw Exp $

EAPI=5

inherit cmake-multilib eutils

DESCRIPTION="universal and secure framework to store config parameters in a hierarchical key-value pair mechanism"
HOMEPAGE="http://freedesktop.org/wiki/Software/Elektra"
SRC_URI="ftp://ftp.markus-raab.org/${PN}/releases/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dbus doc examples iconv inifile simpleini static-libs syslog tcl test xml yajl"

RDEPEND="!amd64? ( dev-libs/libxml2 )
	amd64? (
		abi_x86_64? ( dev-libs/libxml2 )
		abi_x86_32? ( app-emulation/emul-linux-x86-baselibs ) )"
DEPEND="${RDEPEND}
	!amd64? ( sys-devel/libtool )
	doc? ( app-doc/doxygen )
	iconv? ( virtual/libiconv )
	!amd64? ( test? ( dev-libs/libxml2[static-libs] ) )
	yajl? ( <dev-libs/yajl-2 )"

src_configure() {
	local my_plugins="ccode;dump;error;fstab;glob;hexcode;hidden;hosts;network;ni;null;path;resolver;struct;success;template;timeofday;tracer;type;validation"

	#fix QA issues with upstream patches
	epatch "${FILESDIR}/${P}-introduce-attributes.patch"
	epatch "${FILESDIR}/${P}-fix-yajl-if-user-config.patch"

	#move doc files to correct location
	sed -e "s/elektra-api/${PF}/" \
		-i cmake/ElektraCache.cmake || die

	use dbus    && my_plugins+=";dbus"
	use doc     && my_plugins+=";doc"
	use iconv   && my_plugins+=";iconv"
	use inifile && my_plugins+=";simpleini"
	use syslog  && my_plugins+=";syslog"
	use tcl     && my_plugins+=";tcl"
	use xml     && my_plugins+=";xmltool"
	use yajl    && my_plugins+=";yajl"

	mycmakeargs=(
		"-DPLUGINS=${my_plugins}"
		"-DLATEX_COMPILER=OFF"
		"-DTARGET_CMAKE_FOLDER=share/cmake/Modules"
		$(cmake-utils_use doc BUILD_DOCUMENTATION)
		$(cmake-utils_use examples BUILD_EXAMPLES)
		$(cmake-utils_use static-libs BUILD_STATIC)
		$(cmake-utils_use test BUILD_TESTING)
	)

	cmake-multilib_src_configure
}

src_compile() {
	dodir /usr/share/man/man3
	cmake-multilib_src_compile
}

src_install() {
	cmake-multilib_src_install

	dodoc doc/{AUTHORS,CHANGES,NEWS,README,todo/TODO}

	if use doc ; then
		rm -rf "${D}/usr/share/doc/${PF}/man" || die
		pushd ${CMAKE_BUILD_DIR}/doc/man/man3
		local my_f
		for my_f in *.3 ; do
			newman ${my_f} ${PN}-${my_f}
			elog "installed /usr/share/man/man3/${my_f} as ${PN}-${my_f}"
		done
		popd
	fi
}