app-admin/supervisor/supervisor-3.0_alpha9.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/supervisor/supervisor-3.0_alpha9.ebuild,v 1.1 2010/09/23 20:18:45 arfrever Exp $

EAPI="3"
PYTHON_DEPEND="2:2.5"
PYTHON_USE_WITH="xml"
SUPPORT_PYTHON_ABIS="1"
# xml.etree.ElementTree module required.
RESTRICT_PYTHON_ABIS="2.4 3.*"
DISTUTILS_SRC_TEST="setup.py"

inherit distutils eutils

MY_PV="${PV/_alpha/a}"

DESCRIPTION="A system for controlling process state under UNIX"
HOMEPAGE="http://supervisord.org/ http://pypi.python.org/pypi/supervisor"
SRC_URI="http://dist.supervisord.org/${PN}-${MY_PV}.tar.gz"

LICENSE="repoze ZPL BSD as-is"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"

RDEPEND="dev-python/meld3
	dev-python/setuptools"
DEPEND="${RDEPEND}
	test? ( dev-python/mock )"

S="${WORKDIR}/${PN}-${MY_PV}"

DOCS="CHANGES.txt README.txt TODO.txt"

src_prepare() {
	distutils_src_prepare
	epatch "${FILESDIR}/3.0_alpha8-no-docs.patch"
}

src_install() {
	distutils_src_install
	newinitd "${FILESDIR}/init.d" supervisord
	newconfd "${FILESDIR}/conf.d" supervisord
}