app-admin/testdisk/testdisk-6.14-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/testdisk/testdisk-6.14-r1.ebuild,v 1.1 2015/04/24 15:24:10 nicolasbock Exp $

EAPI=5

inherit autotools-utils eutils flag-o-matic

DESCRIPTION="Checks and undeletes partitions + PhotoRec, signature based recovery tool"
HOMEPAGE="http://www.cgsecurity.org/wiki/TestDisk"
SRC_URI="http://www.cgsecurity.org/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~x86"
IUSE="ewf jpeg ntfs reiserfs static qt4"

REQUIRED_USE="static? ( !qt4 )"

# WARNING: reiserfs support does NOT work with reiserfsprogs
# you MUST use progsreiserfs-0.3.1_rc8 (the last version ever released).
DEPEND="
		static? (
			sys-apps/util-linux[static-libs]
			>=sys-libs/ncurses-5.2[static-libs]
			jpeg? ( virtual/jpeg:*[static-libs] )
			ntfs? ( sys-fs/ntfs3g[static-libs] )
			reiserfs? ( >=sys-fs/progsreiserfs-0.3.1_rc8[static-libs] )
			>=sys-fs/e2fsprogs-1.35[static-libs]
			sys-libs/zlib[static-libs]
			!arm? ( ewf? ( app-forensics/libewf:*[static-libs] ) )
			)
		!static? (
			sys-apps/util-linux
			>=sys-libs/ncurses-5.2
			jpeg? ( virtual/jpeg:* )
			ntfs? ( sys-fs/ntfs3g )
			reiserfs? ( >=sys-fs/progsreiserfs-0.3.1_rc8 )
			>=sys-fs/e2fsprogs-1.35
			sys-libs/zlib
			!arm? ( ewf? ( app-forensics/libewf:* ) )
			qt4? ( >=dev-qt/qtgui-4.0.1:* )
			)"
RDEPEND="!static? ( ${DEPEND} )"

PATCHES=(
	"${FILESDIR}/fix_rare_crash-6.14.patch"
	)
DOCS=( )
AUTOTOOLS_AUTORECONF=1
BUILD_DIR="${S}"

src_configure() {
	local myconf

	# this is static method is the same used by upstream for their 'static' make
	# target, but better, as it doesn't break.
	use static && append-ldflags -static

	# --with-foo are broken, any use of --with/--without disable the
	# functionality.
	# The following variation must be used.
	use reiserfs || myconf+=" --without-reiserfs"
	use ntfs || myconf+=" --without-ntfs --without-ntfs3g"
	use jpeg || myconf+=" --without-jpeg"
	use ewf || myconf+=" --without-ewf"
	myconf+=$(usex qt4 " --enable-qt" " --disable-qt")

	econf \
		--docdir "${ROOT}/usr/share/doc/${P}" \
		--enable-sudo \
		${myconf}

	# perform safety checks for NTFS, REISERFS and JPEG
	if use ntfs && ! egrep -q '^#define HAVE_LIBNTFS(3G)? 1$' "${S}"/config.h ; then
		die "Failed to find either NTFS or NTFS-3G library."
	fi
	if use reiserfs && egrep -q 'undef HAVE_LIBREISERFS\>' "${S}"/config.h ; then
		die "Failed to find reiserfs library."
	fi
	if use jpeg && egrep -q 'undef HAVE_LIBJPEG\>' "${S}"/config.h ; then
		die "Failed to find jpeg library."
	fi
}