app-arch/libzpaq/libzpaq-6.41.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/libzpaq/libzpaq-6.41.ebuild,v 1.2 2014/02/19 16:58:02 mgorny Exp $

EAPI=5

AUTOTOOLS_AUTORECONF=1
inherit autotools-utils flag-o-matic eutils

MY_P=zpaq${PV/./}
DESCRIPTION="Library to compress files in the ZPAQ format"
HOMEPAGE="http://mattmahoney.net/dc/zpaq.html"
SRC_URI="http://mattmahoney.net/dc/${MY_P}.zip"

LICENSE="zpaq"
SLOT="0/4"
KEYWORDS="~amd64 ~x86"
IUSE="debug +jit static-libs"

DEPEND="app-arch/unzip"
RDEPEND=""

S=${WORKDIR}

src_prepare() {
	EPATCH_OPTS+=-p1 epatch "${FILESDIR}"/0001-Add-autotools-files.patch
	autotools-utils_src_prepare
}

src_configure() {
	local myeconfargs=(
		--with-library-version=${SLOT#*/}:0:0
	)

	use debug || append-cppflags -DNDEBUG
	use jit || append-cppflags -DNOJIT

	autotools-utils_src_configure
}