dev-go/go-text/go-text-1.4.2_p20150506.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-go/go-text/go-text-1.4.2_p20150506.ebuild,v 1.1 2015/05/21 05:48:42 zmedico Exp $

EAPI=5

KEYWORDS=""
DESCRIPTION="Go text processing support"
MY_PN=${PN##*-}
GO_PN=golang.org/x/${MY_PN}
HOMEPAGE="https://godoc.org/${GO_PN}"
EGIT_COMMIT="c93e7c9fff19fb9139b5ab04ce041833add0134e"
SRC_URI="https://github.com/golang/${MY_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
IUSE=""
DEPEND=">=dev-lang/go-1.4"
RDEPEND=""
S="${WORKDIR}/src/${GO_PN}"
EGIT_CHECKOUT_DIR="${S}"
STRIP_MASK="*.a"

src_unpack() {
	default
	mkdir -p src/${GO_PN%/*} || die
	mv ${MY_PN}-${EGIT_COMMIT} src/${GO_PN} || die
}

src_compile() {
	# Create a writable GOROOT in order to avoid sandbox violations.
	GOROOT="${WORKDIR}/goroot"
	cp -sR "${EPREFIX}"/usr/lib/go "${GOROOT}" || die
	rm -rf "${GOROOT}/src/${GO_PN}" \
		"${GOROOT}/pkg/linux_${ARCH}/${GO_PN}" || die
	GOROOT="${GOROOT}" GOPATH=${WORKDIR} go install -v -x -work ${GO_PN}/... || die
}

src_test() {
	GOROOT="${GOROOT}" GOPATH=${WORKDIR} \
		go test -run "^(Example.*|"$(
			echo -n 'Test(Flush|Insert|Decomposition|Composition|IterNext|'
			echo -n 'IterSegmentation|DecomposeSegment|FirstBoundary|'
			echo -n 'DecomposeToLastBoundary|LastBoundary|QuickSpan|IsNormal|'
			echo -n 'IsNormalString|Append|AppendString|Bytes|String|Reader|'
			echo -n 'Writer|Transform|TransformNorm|CharacterByCharacter|'
			echo -n 'StandardTests|Performance|PlaceHolder|ExampleIter|Merge|'
			echo -n 'Tables|Ambiguous|FoldSingleRunes|Fold|WidenSingleRunes|'
			echo -n 'Widen|NarrowSingleRunes|Narrow))$') \
			-x -v ${GO_PN}/... || die $?
}

src_install() {
	exeinto /usr/lib/go/bin
	doexe "${WORKDIR}"/bin/*
	insinto /usr/lib/go
	find "${WORKDIR}"/{pkg,src} -name '.git*' -exec rm -rf {} \; 2>/dev/null
	doins -r "${WORKDIR}"/{pkg,src}
}