dev-libs/xmlrpc-epi/xmlrpc-epi-0.54.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/xmlrpc-epi/xmlrpc-epi-0.54.2.ebuild,v 1.2 2012/06/16 13:09:20 ago Exp $

EAPI="2"

inherit multilib

DESCRIPTION="Epinions implementation of XML-RPC protocol in C"
HOMEPAGE="http://xmlrpc-epi.sourceforge.net/"
SRC_URI="mirror://sourceforge/xmlrpc-epi/${P}.tar.bz2"

LICENSE="Epinions"
SLOT="0"
KEYWORDS="amd64 ~ppc ~x86"
IUSE="examples static-libs"

DEPEND="dev-libs/expat"
RDEPEND="${DEPEND}"

# NOTES:
# to prevent conflict with xmlrpc-c, headers are installed in
# 	/usr/include/${PN} instead of /usr/include (bug 274291)

src_prepare() {
	# do not build examples
	sed -i -e "s:sample::" Makefile.in || die "sed failed"
}

src_configure() {
	econf \
		--includedir=/usr/include/${PN} \
		--disable-dependency-tracking \
		$(use_enable static-libs static)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	if ! use static-libs; then
		# remove useless la files
		rm "${D}"/usr/$(get_libdir)/lib${PN}.la || die "rm failed"
	fi

	dodoc AUTHORS ChangeLog NEWS README || die "dodoc failed"

	if use examples; then
		insinto "/usr/share/doc/${PF}/examples"
		doins sample/*.c sample/*.php || die "doins failed"
		doins -r sample/tests || die "doins failed"
	fi
}