dev-python/django-extensions/django-extensions-1.3.7.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/django-extensions/django-extensions-1.3.7.ebuild,v 1.2 2014/06/01 02:06:38 idella4 Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7,3_3} )

inherit distutils-r1

GIT_HASH_TAG="8059f05"

DESCRIPTION="Django Command Extensions"
HOMEPAGE="http://github.com/django-extensions/django-extensions http://code.google.com/p/django-command-extensions/"
SRC_URI="http://github.com/django-extensions/django-extensions/tarball/${PV}/${P}.tgz"

LICENSE="BSD || ( MIT GPL-2 )"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc graphviz mysql postgres s3 sqlite test vcard"
# Req'd for tests
DISTUTILS_IN_SOURCE_BUILD=1

PY2_USEDEP=$(python_gen_usedep 'python2*')
RDEPEND=">=dev-python/django-1.5.4[${PYTHON_USEDEP},mysql?,postgres?,sqlite?]
	dev-python/six[${PYTHON_USEDEP}]
	dev-python/pygments[${PYTHON_USEDEP}]
	dev-python/werkzeug[${PYTHON_USEDEP}]
	graphviz? ( dev-python/pygraphviz[${PY2_USEDEP}] )
	s3? ( dev-python/boto[${PY2_USEDEP}] )
	vcard? ( dev-python/vobject[${PY2_USEDEP}] )"
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
	test? ( ${RDEPEND}
		dev-python/shortuuid[${PYTHON_USEDEP}] )"

S="${WORKDIR}/${PN}-${PN}-${GIT_HASH_TAG}"

PY2_REQUSE="|| ( $(python_gen_useflags python2* ) )"
REQUIRED_USE="
	graphviz? ( ${PY2_REQUSE} )
	s3? ( ${PY2_REQUSE} )
	vcard? ( ${PY2_REQUSE} )"

python_compile_all() {
	use doc && emake -C docs html
}

python_test() {
	"${PYTHON}" run_tests.py || die
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/_build/html/. )
	distutils-r1_python_install_all
}