blob: d4159cdb983233e796f377d4207901b88183396c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-control-center/gnome-control-center-3.10.3.ebuild,v 1.6 2014/05/31 22:35:34 ssuominen Exp $
EAPI="5"
GCONF_DEBUG="yes"
GNOME2_LA_PUNT="yes" # gmodule is used, which uses dlopen
inherit autotools bash-completion-r1 eutils gnome2
DESCRIPTION="GNOME's main interface to configure various aspects of the desktop"
HOMEPAGE="https://git.gnome.org/browse/gnome-control-center/"
LICENSE="GPL-2+"
SLOT="2"
IUSE="+bluetooth +colord +cups +gnome-online-accounts +i18n input_devices_wacom kerberos +socialweb v4l"
KEYWORDS="~alpha amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-solaris"
# False positives caused by nested configure scripts
QA_CONFIGURE_OPTIONS=".*"
# gnome-session-2.91.6-r1 is needed so that 10-user-dirs-update is run at login
# g-s-d[policykit] needed for bug #403527
#
# kerberos unfortunately means mit-krb5; build fails with heimdal
# FIXME: modemmanager is not optional
# networkmanager is not optional
COMMON_DEPEND="
>=dev-libs/glib-2.37.2:2
>=x11-libs/gdk-pixbuf-2.23.0:2
>=x11-libs/gtk+-3.9.12:3
>=gnome-base/gsettings-desktop-schemas-3.9.91
>=gnome-base/gnome-desktop-3.9.90:3=
>=gnome-base/gnome-settings-daemon-3.8.3[colord?,policykit]
>=dev-libs/libpwquality-1.2.2
dev-libs/libxml2:2
gnome-base/gnome-menus:3
gnome-base/libgtop:2
media-libs/fontconfig
>=media-libs/libcanberra-0.13[gtk3]
>=media-sound/pulseaudio-2[glib]
>=sys-auth/polkit-0.97
|| ( >=sys-power/upower-0.9.1 sys-power/upower-pm-utils )
>=x11-libs/libnotify-0.7.3:0=
>=gnome-extra/nm-applet-0.9.7.995
>=net-misc/networkmanager-0.9.8[modemmanager]
>=net-misc/modemmanager-0.7.990
virtual/opengl
x11-apps/xmodmap
x11-libs/libX11
x11-libs/libXxf86misc
>=x11-libs/libXi-1.2
bluetooth? ( >=net-wireless/gnome-bluetooth-3.9.3:= )
colord? (
net-libs/libsoup:2.4
>=x11-misc/colord-0.1.34:0=
>=x11-libs/colord-gtk-0.1.24 )
cups? (
>=net-print/cups-1.4[dbus]
|| ( >=net-fs/samba-3.6.14-r1[smbclient] >=net-fs/samba-4.0.0[client] ) )
gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.9.90 )
i18n? ( >=app-i18n/ibus-1.5.2 )
kerberos? ( app-crypt/mit-krb5 )
socialweb? ( net-libs/libsocialweb )
v4l? (
media-libs/gstreamer:1.0
media-libs/clutter-gtk:1.0
>=media-video/cheese-3.5.91 )
input_devices_wacom? (
>=dev-libs/libwacom-0.7
>=media-libs/clutter-1.11.3:1.0
media-libs/clutter-gtk:1.0
>=x11-libs/libXi-1.2 )
"
# <gnome-color-manager-3.1.2 has file collisions with g-c-c-3.1.x
# libgnomekbd needed only for gkbd-keyboard-display tool
RDEPEND="${COMMON_DEPEND}
|| ( ( app-admin/openrc-settingsd sys-auth/consolekit ) >=sys-apps/systemd-31 )
>=sys-apps/accountsservice-0.6.30
x11-themes/gnome-icon-theme-symbolic
colord? ( >=gnome-extra/gnome-color-manager-3 )
cups? (
>=app-admin/system-config-printer-gnome-1.3.5
net-print/cups-pk-helper )
i18n? ( >=gnome-base/libgnomekbd-3 )
input_devices_wacom? ( gnome-base/gnome-settings-daemon[input_devices_wacom] )
!<gnome-base/gdm-2.91.94
!<gnome-extra/gnome-color-manager-3.1.2
!gnome-extra/gnome-media[pulseaudio]
!<gnome-extra/gnome-media-2.32.0-r300
!<net-wireless/gnome-bluetooth-3.3.2
"
# PDEPEND to avoid circular dependency
PDEPEND=">=gnome-base/gnome-session-2.91.6-r1"
DEPEND="${COMMON_DEPEND}
x11-proto/xproto
x11-proto/xf86miscproto
x11-proto/kbproto
dev-libs/libxml2:2
dev-libs/libxslt
>=dev-util/intltool-0.40.1
>=sys-devel/gettext-0.17
virtual/pkgconfig
cups? ( sys-apps/sed )
gnome-base/gnome-common
"
# Needed for autoreconf
# gnome-base/gnome-common
src_prepare() {
# Gentoo handles completions in a different directory, bugs #465094 and #477390
sed -i "s|^completiondir =.*|completiondir = $(get_bashcompdir)|" \
shell/Makefile.am || die "sed completiondir failed"
# Make some panels and dependencies optional; requires eautoreconf
# https://bugzilla.gnome.org/686840, 697478, 700145
epatch "${FILESDIR}"/${PN}-3.10.2-optional.patch
# Fix some absolute paths to be appropriate for Gentoo
epatch "${FILESDIR}"/${PN}-3.10.2-gentoo-paths.patch
epatch_user
eautoreconf
# panels/datetime/Makefile.am gets touched by "gentoo-paths" patch.
# We need to touch timedated{c,h} to prevent them from being
# regenerated (bug #415901)
# Upstream think they should be removed, preventing compilation errors too
# (https://bugzilla.gnome.org/704822)
[[ -f panels/datetime/timedated.h ]] && rm -f panels/datetime/timedated.h
[[ -f panels/datetime/timedated.c ]] && rm -f panels/datetime/timedated.c
gnome2_src_prepare
}
src_configure() {
gnome2_src_configure \
--disable-update-mimedb \
--disable-static \
--enable-documentation \
$(use_enable bluetooth) \
$(use_enable colord color) \
$(use_enable cups) \
$(use_enable gnome-online-accounts goa) \
$(use_enable i18n ibus) \
$(use_enable kerberos) \
$(use_with socialweb libsocialweb) \
$(use_with v4l cheese) \
$(use_enable input_devices_wacom wacom)
}
|
GitWeb