media-gfx/gthumb/gthumb-2.8.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/gthumb/gthumb-2.8.1.ebuild,v 1.5 2007/03/20 15:22:27 dang Exp $

WANT_AUTOCONF="2.5"
WANT_AUTOMAKE="1.8"

inherit eutils autotools gnome2

DESCRIPTION="Image viewer and browser for Gnome"
HOMEPAGE="http://gthumb.sourceforge.net/"
LICENSE="GPL-2"

IUSE="exif gphoto2 jpeg tiff"
SLOT="0"
KEYWORDS="amd64 ~ia64 ~ppc ~ppc64 x86"

RDEPEND=">=dev-libs/glib-2.6
	>=x11-libs/gtk+-2.8
	>=dev-libs/libxml2-2.4
	>=gnome-base/libgnome-2.6
	>=gnome-base/libgnomeui-2.6
	>=gnome-base/libgnomecanvas-2.6
	>=gnome-base/gnome-vfs-2.6
	>=gnome-base/libglade-2.4
	>=gnome-base/libgnomeprint-2.6
	>=gnome-base/libgnomeprintui-2.6
	>=gnome-base/libbonobo-2.6
	>=gnome-base/libbonoboui-2.6
	>=gnome-base/gconf-2.6
	exif? ( >=media-libs/libexif-0.6.9 )
	gphoto2? ( >=media-libs/libgphoto2-2.1.3 )
	jpeg? ( media-libs/jpeg )
	tiff? ( media-libs/tiff )"

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.9.0
	app-text/scrollkeeper
	>=dev-util/intltool-0.29"

DOCS="AUTHORS COPYING ChangeLog INSTALL NEWS README"

pkg_setup() {
	G2CONF="$(use_enable exif) \
		$(use_enable gphoto2) \
		$(use_enable jpeg) \
		$(use_enable tiff)"
}

src_unpack() {
	gnome2_src_unpack

	# as-needed #130284
	# New as-needed, including gphoto fixes
	epatch "${FILESDIR}/${PN}-2.8.1-as-needed.patch"

	# Respect zoom preferences.  Bug #156342
	epatch "${FILESDIR}/${PN}-2.8.1-respect-zoom-pref.patch"

	# Fix compilation if USE=-exif (bug #163533)
	epatch "${FILESDIR}/${P}-noexif_fixes.patch"

	eautoreconf
}