media-sound/aumix/aumix-2.8.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/aumix/aumix-2.8.ebuild,v 1.2 2003/02/13 13:08:12 vapier Exp $

IUSE="gpm nls gtk gnome alsa gtk2"

DESCRIPTION="Aumix volume/mixer control program."
SRC_URI="http://jpj.net/~trevor/aumix/${P}.tar.bz2"
HOMEPAGE="http://jpj.net/~trevor/aumix/"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~x86"

DEPEND=">=sys-libs/ncurses-5.2
	gpm?  ( >=sys-libs/gpm-1.19.3 )
	alsa? ( >=media-libs/alsa-lib-0.9.0_rc1 )
	gtk?  ( =x11-libs/gtk+-1.2* )
	gtk2? ( >=x11-libs/gtk+-2.0.0 )
	nls?  ( sys-devel/gettext )"

src_compile() {
	local myconf
	
	if use gtk2; then 
		myconf="${myconf} --without-gtk1" 
	elif use gtk; then 
		myconf="${myconf} --without-gtk" 
	else
		myconf="${myconf} --without-gtk --without-gtk1";
	fi

	use gpm  || myconf="${myconf} --without-gpm"
	use nls  || myconf="${myconf} --disable-nls"
	use alsa || myconf="${myconf} --without-alsa"
	
	econf ${myconf}
	emake || die "make failed"
}

src_install() {
	einstall
	
	dodoc AUTHORS BUGS COPYING ChangeLog NEWS README TODO
	
	if use gnome; then
		insinto /usr/share/gnome/apps/Multimedia
		doins ${FILESDIR}/aumix.desktop
		dodir /usr/share/pixmaps
		ln -s ../aumix/aumix.xpm ${D}/usr/share/pixmaps
	fi
	
	exeinto /etc/init.d ; newexe ${FILESDIR}/aumix.rc6 aumix
}